summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorWade Cline <wadecline@hotmail.com>2020-04-19 17:37:19 -0700
committerJoonas Niilola <juippis@gentoo.org>2020-04-21 15:44:50 +0300
commitf941f97c9fc52af501be036aed3b36389d6d6bd9 (patch)
tree1e54327942c4552b630e97f1f2f3e85314c9f41c /net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild
parentapp-crypt/nitrocli: Bump version to 0.3.3 (diff)
downloadgentoo-f941f97c9fc52af501be036aed3b36389d6d6bd9.tar.gz
gentoo-f941f97c9fc52af501be036aed3b36389d6d6bd9.tar.bz2
gentoo-f941f97c9fc52af501be036aed3b36389d6d6bd9.zip
net-irc/atheme-services: Rev bump
Fix dependencies. Closes: https://bugs.gentoo.org/717832 Signed-off-by: Wade Cline <wadecline@hotmail.com> Closes: https://github.com/gentoo/gentoo/pull/15434 Signed-off-by: Joonas Niilola <juippis@gentoo.org>
Diffstat (limited to 'net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild')
-rw-r--r--net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild94
1 files changed, 94 insertions, 0 deletions
diff --git a/net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild b/net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild
new file mode 100644
index 000000000000..820dfd3bd2f6
--- /dev/null
+++ b/net-irc/atheme-services/atheme-services-7.2.10_p2-r2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic perl-functions
+
+MY_PN="atheme"
+MY_PV="7.2.10-r2"
+
+DESCRIPTION="A portable and secure set of open-source and modular IRC services"
+HOMEPAGE="https://github.com/atheme/atheme"
+SRC_URI="https://github.com/atheme/atheme/releases/download/v${MY_PV}/${MY_PN}-v${MY_PV}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cracklib largenet ldap nls +pcre perl profile ssl"
+S="${WORKDIR}/${MY_PN}-v${MY_PV}"
+
+RDEPEND="
+ acct-group/atheme-services
+ acct-user/atheme-services
+ >=dev-libs/libmowgli-2.1.0:2
+ cracklib? ( sys-libs/cracklib )
+ ldap? ( net-nds/openldap )
+ perl? ( dev-lang/perl )
+ pcre? ( dev-libs/libpcre )
+ ssl? ( dev-libs/openssl:0= )"
+DEPEND="${RDEPEND}"
+# 'dev-vcs/git' required as per bug #665802
+BDEPEND="
+ dev-vcs/git
+ virtual/pkgconfig"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-configure-logdir.patch
+ "${FILESDIR}"/${P}-fix-backtrace-compat-detection.patch)
+
+src_configure() {
+ # perl scriping module support is also broken in 7.0.0. Yay for QA failures.
+ econf \
+ --sysconfdir="${EPREFIX}"/etc/${PN} \
+ --localstatedir="${EPREFIX}"/var \
+ --enable-fhs-paths \
+ --disable-warnings \
+ --enable-contrib \
+ $(use_enable largenet large-net) \
+ $(use_with cracklib) \
+ $(use_with ldap) \
+ $(use_enable nls) \
+ $(use_enable profile) \
+ $(use_with pcre) \
+ $(use_with perl) \
+ $(use_enable ssl)
+}
+
+src_compile() {
+ emake V=1
+}
+
+src_install() {
+ default
+
+ insinto /etc/${PN}
+ for conf in dist/*.example; do
+ # The .cron file isn't meant to live in /etc/${PN}, so only
+ # install a .example version.
+ [[ ${conf} == *cron* ]] && continue
+
+ local confdest=${conf##*/}
+ newins ${conf} ${confdest%.example}
+ done
+
+ fowners -R 0:${PN} /etc/${PN}
+ keepdir /var/{lib,log}/atheme
+ fowners ${PN}:${PN} /var/{lib,log}/atheme
+ fperms -R go-w,o-rx /etc/${PN}
+ fperms 750 /etc/${PN} /var/{lib,log}/atheme
+
+ newinitd "${FILESDIR}"/${PN}.initd ${PN}
+ mv "${ED}"/usr/bin/{,atheme-}dbverify || die
+
+ # contributed scripts and such:
+ docinto contrib
+ dodoc contrib/*.{c,pl,php,py,rb}
+
+ use perl && perl_domodule -r contrib/Atheme{,.pm}
+
+ rm "${ED}/usr/share/doc/${PF}/WINDOWS" || die
+
+ # Bug #454840 #520490
+ rm -rf "${ED}/var/run" || die
+}