net-irc/irssi: Version bump (v1.2.2)

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

1 files changed, 65 insertions, 0 deletions

diff --git a/net-irc/irssi/irssi-1.2.2.ebuild b/net-irc/irssi/irssi-1.2.2.ebuild
new file mode 100644
index 000000000000..07e3cb75fc68
--- /dev/null
+++ b/net-irc/irssi/irssi-1.2.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit perl-module
+
+# Keep for _rc compability
+MY_P="${P/_/-}"
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="https://irssi.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="otr +perl selinux socks5 +proxy libressl"
+
+COMMON_DEPEND="
+	sys-libs/ncurses:0=
+	>=dev-libs/glib-2.6.0
+	!net-irc/irssi-otr
+	!libressl? ( dev-libs/openssl:= )
+	libressl? ( >=dev-libs/libressl-2.7.4:= )
+	otr? ( >=dev-libs/libgcrypt-1.2.0:0=
+		>=net-libs/libotr-4.1.0 )
+	perl? ( dev-lang/perl:= )
+	socks5? ( >=net-proxy/dante-1.1.18 )"
+
+DEPEND="
+	${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	selinux? ( sec-policy/selinux-irc )
+	perl? ( !net-im/silc-client )"
+
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	# Disable automagic dependency on dev-libs/libutf8proc (bug #677804)
+	export ac_cv_lib_utf8proc_utf8proc_version=no
+
+	local myeconfargs=(
+		--with-perl-lib=vendor
+		--enable-true-color
+		$(use_with otr)
+		$(use_with proxy)
+		$(use_with perl)
+		$(use_with socks5 socks)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	use perl && perl_delete_localpod
+	rm -f "${ED}"/usr/$(get_libdir)/irssi/modules/*.{a,la}
+}