summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNP-Hardass <NP-Hardass@gentoo.org>2019-12-02 09:48:09 -0500
committerGöktürk Yüksek <gokturk@gentoo.org>2019-12-02 12:21:41 -0500
commit7be52f52d69834fb3d5b59fd75df09bf2b64aee3 (patch)
tree1466b4f4b0d0f7aee8c0f236804a521ce3ddb9e4 /net-irc/limnoria/limnoria-20191123.ebuild
parentx11-drivers/xf86-input-wacom: Update remote id to github (diff)
downloadgentoo-7be52f52d69834fb3d5b59fd75df09bf2b64aee3.tar.gz
gentoo-7be52f52d69834fb3d5b59fd75df09bf2b64aee3.tar.bz2
gentoo-7be52f52d69834fb3d5b59fd75df09bf2b64aee3.zip
net-irc/limnoria: Bump to 20191123 & EAPI 7, update PYCOMPAT
CVE: CVE-2019-19010 Bug: https://bugs.gentoo.org/701756 Package-Manager: Portage-2.3.80, Repoman-2.3.16 Signed-off-by: NP-Hardass <NP-Hardass@gentoo.org> Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>
Diffstat (limited to 'net-irc/limnoria/limnoria-20191123.ebuild')
-rw-r--r--net-irc/limnoria/limnoria-20191123.ebuild88
1 files changed, 88 insertions, 0 deletions
diff --git a/net-irc/limnoria/limnoria-20191123.ebuild b/net-irc/limnoria/limnoria-20191123.ebuild
new file mode 100644
index 000000000000..3b1067c7a695
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20191123.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == "99999999" ]]; then
+ EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+ EGIT_BRANCH="testing"
+ inherit git-r3
+ SRC_URI=""
+else
+ SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+ S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://supybot.aperio.fr/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="crypt ssl test"
+
+RDEPEND="
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/ecdsa[${PYTHON_USEDEP}]
+ dev-python/feedparser[${PYTHON_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/PySocks[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+ ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+ !net-irc/supybot
+ !net-irc/supybot-plugins
+ "
+DEPEND="${RDEPEND}
+ test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+src_unpack() {
+ if [[ ${PV} == "99999999" ]]; then
+ git-r3_src_unpack
+ else
+ unpack ${P}.tar.gz
+ fi
+}
+
+python_prepare(){
+ if python_is_python3; then
+ einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+ einfo "bindings and feedparser."
+ rm -rf "plugins/RSS" || die
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ doman man/*
+}
+
+python_test() {
+ pushd "${T}" > /dev/null
+ PLUGINS_DIR="${BUILD_DIR}/lib/supybot/plugins"
+ EXCLUDE_PLUGINS=()
+ # intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+ # runs successfully when running the tests on the installed system
+ EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+ # Runs despite --no-network (GH #1392)
+ EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Aka" )
+ "${PYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+ --plugins-dir="${PLUGINS_DIR}" --no-network \
+ --disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+ || die "Tests failed under ${EPYTHON}"
+ popd > /dev/null
+}
+
+pkg_postinst() {
+ elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+ elog ""
+ elog "Use supybot-wizard to create a configuration file."
+ elog "Run supybot </path/to/config> to use the bot."
+}