summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James (sam_c) <sam@cmpct.info>2020-06-20 17:08:47 +0000
committerThomas Deutschmann <whissi@gentoo.org>2020-06-20 22:30:45 +0200
commit3948f96270865b75fe4e81b63edceb12e1db3888 (patch)
treecdef1a837c088bc03de8760c3dc77aa54b2b8828 /net-irc/ngircd/ngircd-26.ebuild
parentprofiles: Mask media-libs/pymemphis for removal (diff)
downloadgentoo-3948f96270865b75fe4e81b63edceb12e1db3888.tar.gz
gentoo-3948f96270865b75fe4e81b63edceb12e1db3888.tar.bz2
gentoo-3948f96270865b75fe4e81b63edceb12e1db3888.zip
net-irc/ngircd: bump to 26
Notes: * Tests still disabled; going to speak to upstream about the one flaky test for now. They are somewhat interdependent so I'm not keen on disabling just one yet. If we can't establish why, we will skip it, but given the nature of the tests (connecting to a spawned instance, etc), the failure could be generic to all of the tests. * PAMOnly -> PAMIsOptional in config, backwards compatible Please see upstream release notes for more information. Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Sam James (sam_c) <sam@cmpct.info> Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
Diffstat (limited to 'net-irc/ngircd/ngircd-26.ebuild')
-rw-r--r--net-irc/ngircd/ngircd-26.ebuild106
1 files changed, 106 insertions, 0 deletions
diff --git a/net-irc/ngircd/ngircd-26.ebuild b/net-irc/ngircd/ngircd-26.ebuild
new file mode 100644
index 000000000000..06a17a180d81
--- /dev/null
+++ b/net-irc/ngircd/ngircd-26.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Bug: https://github.com/ngircd/ngircd/issues/261
+WANT_AUTOMAKE=1.11.6
+inherit autotools
+
+DESCRIPTION="An IRC server written from scratch"
+HOMEPAGE="https://ngircd.barton.de/"
+SRC_URI="https://arthur.barton.de/pub/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~x64-macos"
+IUSE="debug gnutls ident irc-plus +ipv6 libressl pam +ssl strict-rfc tcpd test zlib"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ acct-user/ngircd
+ acct-group/ngircd
+ irc-plus? ( virtual/libiconv )
+ ident? ( net-libs/libident )
+ pam? ( sys-libs/pam )
+ ssl? (
+ gnutls? ( net-libs/gnutls:= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+ )
+ tcpd? ( sys-apps/tcp-wrappers )
+ zlib? ( sys-libs/zlib )
+"
+
+BDEPEND="sys-devel/automake:1.11"
+
+DEPEND="
+ ${RDEPEND}
+ test? (
+ dev-tcltk/expect
+ net-misc/netkit-telnetd
+ )
+"
+
+# Flaky test needs investigation (bug 719256)
+RESTRICT="test"
+
+src_prepare() {
+ default
+
+ if ! use prefix; then
+ sed -i \
+ -e "s:;ServerUID = 65534:ServerUID = ngircd:" \
+ -e "s:;ServerGID = 65534:ServerGID = ngircd:" \
+ doc/sample-ngircd.conf.tmpl || die
+ fi
+
+ # Once https://github.com/ngircd/ngircd/pull/270 is in a release (ngircd 26), we can remove
+ # the eautomake/autotools machinery.
+ eautomake
+}
+
+src_configure() {
+ local myconf=(
+ --sysconfdir="${EPREFIX}"/etc/"${PN}"
+ $(use_enable debug sniffer)
+ $(use_enable debug)
+ $(use_enable irc-plus ircplus)
+ $(use_enable ipv6)
+ $(use_enable strict-rfc)
+ $(use_with irc-plus iconv)
+ $(use_with ident)
+ $(use_with pam)
+ $(use_with tcpd tcp-wrappers)
+ $(use_with zlib)
+ )
+
+ if use ssl; then
+ if use gnutls; then
+ myconf+=(
+ $( use_with gnutls )
+ )
+ else
+ myconf+=(
+ $( use_with !gnutls openssl )
+ )
+ fi
+ fi
+
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+ newinitd "${FILESDIR}"/ngircd.init-r1.d ngircd
+}
+
+pkg_postinst() {
+ if [[ -z ${REPLACING_VERSIONS} ]] && use pam; then
+ elog "ngircd will use PAMIsOptionalPAM by default, please change this option."
+ elog "You may not be able to login until you change this."
+ fi
+}