net-misc/modemmanager: Version bump

Package-Manager: portage-2.3.0_rc1

2 files changed, 109 insertions, 0 deletions

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index b0fc1f5b3ffa..137e9cb044fc 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1 +1,2 @@
 DIST ModemManager-1.4.12.tar.xz 1407168 SHA256 7ef5035375a953b285a742591df0a65fd442f4641ce4d8f4392a41d6d6bc70b3 SHA512 f3d8bfdfc5df14c866a4fd2c0ef125c818fc5b2464d166dee2ad2b8df3d9ee22667f521313e664b2a6d8e7f72a965929cb815ad4f7a6a1ecbd17957bfde720ee WHIRLPOOL d8b2cbeb08fbdf5cdee6b7a44b49b415ee31c5e78651e7e6c12a5c8f0aa9d828ab4ce0db40bc4b87592944a221ed815bea9243debb8b6647a687a85e93362626
+DIST ModemManager-1.4.14.tar.xz 1417092 SHA256 abe6cdd515a774bcba3afdcdb1e504569801e79282ccdf26099f33cbb8731ba2 SHA512 2fb5517cd3fbd98cf4048cec326fabf18fb26d88b75e56208d1ed64d70d72d6e826ef30391c86fbcfe4d69661194bcfbb55d545db10ebe8baf8ef16a3c580446 WHIRLPOOL 30c9e1e388c91f8aab73044634e3d122636f526cb9b437a597dc2f35cfd85e61917a568cfa572404f734eb19eb90c2e21bc85e16d6cc9b53518f590981f6efa4
diff --git a/net-misc/modemmanager/modemmanager-1.4.14.ebuild b/net-misc/modemmanager/modemmanager-1.4.14.ebuild
new file mode 100644
index 000000000000..cc991b6118fa
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-1.4.14.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 user readme.gentoo-r1 udev vala
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="https://cgit.freedesktop.org/ModemManager/ModemManager/"
+SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="+introspection mbim policykit +qmi qmi-newest vala"
+REQUIRED_USE="
+	qmi-newest? ( qmi )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	virtual/libgudev:=
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	mbim? ( >=net-libs/libmbim-1.10 )
+	policykit? ( >=sys-auth/polkit-0.106[introspection] )
+	qmi? ( >=net-libs/libqmi-1.12.4:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/ModemManager-${PV}"
+
+src_prepare() {
+	DOC_CONTENTS="If your USB modem shows up as a Flash drive when you plug it in,
+		You should install sys-apps/usb_modeswitch which will automatically
+		switch it over to USB modem mode whenever you plug it in.\n"
+
+	if use policykit; then
+		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
+			add your user account to the 'plugdev' group."
+	fi
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--with-udev-base-dir="$(get_udevdir)" \
+		--disable-static \
+		--with-dist-version=${PVR} \
+		$(use_enable introspection) \
+		$(use_with mbim) \
+		$(use_with policykit polkit) \
+		$(use_with qmi) \
+		$(use_with qmi-newest newest-qmi-commands) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Allow users in plugdev group full control over their modem
+	if use policykit; then
+		insinto /usr/share/polkit-1/rules.d/
+		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use policykit && enewgroup plugdev
+
+	# The polkit rules file moved to /usr/share
+	old_rules="${EROOT}etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
+	if [[ -f "${old_rules}" ]]; then
+		case "$(md5sum ${old_rules})" in
+		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
+			# Automatically delete the old rules.d file if the user did not change it
+			elog
+			elog "Removing old ${old_rules} ..."
+			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
+			;;
+		  * )
+			elog "The ${old_rules}"
+			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
+			elog "If you edited ${old_rules}"
+			elog "without changing its behavior, you may want to remove it."
+			;;
+		esac
+	fi
+
+	readme.gentoo_print_elog
+}