summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2021-06-30 19:38:50 +0100
committerSam James <sam@gentoo.org>2021-06-30 19:38:50 +0100
commitd2e44fa7b4e732f46ffc00896550f1ffa30ccd03 (patch)
tree592c6b3e2e4e8549975d36c6db9d57a07d504dea /net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild
parentnet-nds/yp-tools: add misisng libcrypt dependency (diff)
downloadgentoo-d2e44fa7b4e732f46ffc00896550f1ffa30ccd03.tar.gz
gentoo-d2e44fa7b4e732f46ffc00896550f1ffa30ccd03.tar.bz2
gentoo-d2e44fa7b4e732f46ffc00896550f1ffa30ccd03.zip
net-nds/tac_plus: add missing libcrypt dependency
Signed-off-by: Sam James <sam@gentoo.org>
Diffstat (limited to 'net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild')
-rw-r--r--net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild68
1 files changed, 68 insertions, 0 deletions
diff --git a/net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild b/net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild
new file mode 100644
index 000000000000..694c6a330c3f
--- /dev/null
+++ b/net-nds/tac_plus/tac_plus-4.0.4.27a-r3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools pam
+
+MY_P="tacacs+-F${PV}"
+DESCRIPTION="An updated version of Cisco's TACACS+ server"
+HOMEPAGE="http://www.shrubbery.net/tac_plus/"
+SRC_URI="ftp://ftp.shrubbery.net/pub/tac_plus/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND RSA GPL-2" # GPL-2 only for init script
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug finger maxsess tcpd skey static-libs"
+
+DEPEND="
+ net-libs/libnsl:=
+ sys-libs/pam
+ virtual/libcrypt:=
+ skey? ( >=sys-auth/skey-1.1.5-r1 )
+ tcpd? ( sys-apps/tcp-wrappers )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+ "${FILESDIR}/${P}-parallelmake.patch"
+ "${FILESDIR}/${PN}-4.0.4.19-deansification.patch"
+)
+
+src_prepare() {
+ default
+
+ mv configure.in configure.ac || die "Unable to quiet autoconf deprecation warning"
+ AT_M4DIR="." eautoreconf
+
+}
+
+src_configure() {
+ econf \
+ $(use_with skey) \
+ $(use_with tcpd libwrap) \
+ $(use_enable debug) \
+ $(use_enable finger) \
+ $(use_enable maxsess) \
+ $(use_enable static-libs static)
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+
+ if use static-libs ; then
+ find "${ED}" -name '*.la' -delete || die "Unable to remove spurious libtool archive"
+ fi
+
+ dodoc CHANGES FAQ
+
+ newinitd "${FILESDIR}/tac_plus.init2" tac_plus
+ newconfd "${FILESDIR}/tac_plus.confd2" tac_plus
+
+ # bug #474860
+ pamd_mimic_system tac_plus auth account password session
+
+ insinto /etc/tac_plus
+ newins "${FILESDIR}/tac_plus.conf2" tac_plus.conf
+}