net-nntp/suck: Version bump, 4.3.4

Closes: https://bugs.gentoo.org/696724
Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 61 insertions, 0 deletions

diff --git a/net-nntp/suck/suck-4.3.4.ebuild b/net-nntp/suck/suck-4.3.4.ebuild
new file mode 100644
index 000000000000..6e3a5533c5c3
--- /dev/null
+++ b/net-nntp/suck/suck-4.3.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="Grab news from a remote NNTP server and feed them to another"
+HOMEPAGE="https://lazarus-pkgs.github.io/lazarus-pkgs/suck.html"
+SRC_URI="https://github.com/lazarus-pkgs/suck/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="perl ssl libressl"
+
+RDEPEND="
+	sys-libs/gdbm:=
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-libs/db
+	perl? ( dev-lang/perl )
+"
+
+src_prepare() {
+	default
+
+	# Fix paths to the locations in Gentoo
+	sed -i \
+		-e 's:/usr/bin/rnews:/usr/$(get_libdir)/news/bin/rnews:' \
+		-e 's:/var/lib/news/history:/var/spool/news/db/history:' \
+		suck_config.h || die "path adaption sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	use ssl || sed -i -e 's/^SSL_/#SSL_/' Makefile.in || die "ssl sed failed"
+	use perl || sed -i -e 's/^PERL_/#PERL_/' Makefile.in || die "perl sed failed"
+
+	econf --without-inn-lib --without-inn-include
+}
+
+src_compile() {
+	emake phrases.h
+	emake all lpost
+}
+
+src_install() {
+	dobin lmove lpost rpost suck testhost
+	doman man/*
+	dodoc CHANGELOG CONTENTS README*
+	docinto java
+	dodoc java/*
+	docinto perl
+	dodoc perl/*
+	docinto sample
+	dodoc sample/*
+}