summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2018-12-03 12:21:45 +0100
committerLars Wendler <polynomial-c@gentoo.org>2018-12-03 12:40:45 +0100
commit9f449b395143388d46551b540f706c4a598bb83f (patch)
tree5e8e60542b9f2d4e630027634fb0e424a9df20f0 /sys-fs/mtools/mtools-4.0.22.ebuild
parentmedia-gfx/gthumb: bump to 3.6.2 (diff)
downloadgentoo-9f449b395143388d46551b540f706c4a598bb83f.tar.gz
gentoo-9f449b395143388d46551b540f706c4a598bb83f.tar.bz2
gentoo-9f449b395143388d46551b540f706c4a598bb83f.zip
sys-fs/mtools: Bump to version 4.0.22
Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'sys-fs/mtools/mtools-4.0.22.ebuild')
-rw-r--r--sys-fs/mtools/mtools-4.0.22.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/sys-fs/mtools/mtools-4.0.22.ebuild b/sys-fs/mtools/mtools-4.0.22.ebuild
new file mode 100644
index 000000000000..651e08e2c962
--- /dev/null
+++ b/sys-fs/mtools/mtools-4.0.22.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit flag-o-matic
+
+DESCRIPTION="utilities to access MS-DOS disks from Unix without mounting them"
+HOMEPAGE="https://www.gnu.org/software/mtools/ https://savannah.gnu.org/projects/mtools"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x64-solaris"
+IUSE="X elibc_glibc"
+
+RDEPEND="
+ !elibc_glibc? ( virtual/libiconv )
+ X? (
+ x11-libs/libICE
+ x11-libs/libXau
+ x11-libs/libSM
+ x11-libs/libX11
+ x11-libs/libXt
+ )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+ default
+
+ # Don't throw errors on existing directories
+ sed -i -e "s:mkdir:mkdir -p:" mkinstalldirs || die
+}
+
+src_configure() {
+ # 447688
+ use !elibc_glibc && use !elibc_musl && append-libs "-liconv"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX%/}"/etc/mtools
+ $(use_with X x)
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ local -a DOCS=( README* Release.notes )
+ default
+
+ insinto /etc/mtools
+ doins mtools.conf
+
+ # default is fine
+ sed -i -e '/^SAMPLE FILE$/s:^:#:' "${ED%/}"/etc/mtools/mtools.conf || die
+}