summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorStephan Hartmann <sultan@gentoo.org>2021-12-27 12:19:34 +0100
committerStephan Hartmann <sultan@gentoo.org>2021-12-27 12:19:34 +0100
commit6cff422d855688d5d664a972f03e2fc855373282 (patch)
tree4b301c858471b7994aaa79308b5dfcf19407387f /www-client/opera-beta
parentwww-client/opera-developer: remove old (diff)
downloadgentoo-6cff422d855688d5d664a972f03e2fc855373282.tar.gz
gentoo-6cff422d855688d5d664a972f03e2fc855373282.tar.bz2
gentoo-6cff422d855688d5d664a972f03e2fc855373282.zip
www-client/opera-beta: bump to 83.0.4254.5
Package-Manager: Portage-3.0.28, Repoman-3.0.3 Signed-off-by: Stephan Hartmann <sultan@gentoo.org>
Diffstat (limited to 'www-client/opera-beta')
-rw-r--r--www-client/opera-beta/Manifest1
-rw-r--r--www-client/opera-beta/opera-beta-83.0.4254.5.ebuild157
2 files changed, 158 insertions, 0 deletions
diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index c9966275be24..50ef75c2e321 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
DIST opera-beta_81.0.4196.14_amd64.deb 79296820 BLAKE2B 5cf8649a3ba84eef8bd76fb8b2cc41d4a66ab1dfb94a1a29a8ee40af3bb0fb891359c544d5d650f84afb7b509b0fa383651c30bdfb085a5c87f678755e4cb473 SHA512 ef087f23ac8e475dce4792100d856b7392b3eb70ddd53e7e88e6ede81003a76cc041c26d3d030d78e4bea1c7bf1e57734c8349a290ddce9357d00eb12b67d132
DIST opera-beta_81.0.4196.27_amd64.deb 79303532 BLAKE2B a542d564c2ad13358b507d4f0ae15e2301750fff0f2ab1246f0152602aad10110c47bf963b674cf5367702fc3af4bf4309d74644fa787a04f5acb89245d271b6 SHA512 91067dea167d08f2730c802652dbbb7d4e4e600190ee2d464c2dced5db226a08ec0620516626f0495d3c1893fec4e89919aee7e1f26777d82e08100be0c5ca98
DIST opera-beta_82.0.4227.7_amd64.deb 80081488 BLAKE2B dae523753048e7542b720debe687ae3a632a26d9117d936d821f2c3426a92a3ece00d0e763d0a1e94da097d41030fd51b0f4ebed487b7c4d9a38a0b6e6eb52ba SHA512 2a9cc3b626b77bd139fe40fabe226b6c0b76500d3325262fa77ace39f06444fe35762415ab8be64766876296dbaa55b54312d218be74d6555f28065ea7a35bde
+DIST opera-beta_83.0.4254.5_amd64.deb 79966836 BLAKE2B f8cafe88945791bfde2814c4767dbb53d919968cb33c96462b2108cd8b6cb27139681236c7c4f5350553f4b8a9de3042e1545be2aa9632ab49d1b99b545592d7 SHA512 ce9ea16d1e48add0d32eb9898aa894bb963318f73a6eacdd4e78d793f861c59091d6a39545dcaed5031c63dac12828e7abd36b091756dd351596d28787020bcf
DIST opera-ffmpeg-codecs-94.0.4603.0.tar.xz 1388572 BLAKE2B 55a598883dfbab598f48a662009ab02c4974a95ba023e3b2d36bdad3267ab4586cfd05891f83a96933b6b0b02dc1d2a496bb796ecb5421635a370f6c79c60a98 SHA512 dfeb7174ad5d696f78a86735462757d0245aecf0d00c21ba6ff3c16f6af586979457ebb23db228f3769cf09636ed70421aafe29eb622ca658e766dafc860827a
DIST opera-ffmpeg-codecs-96.0.4655.7.tar.xz 1394152 BLAKE2B a48c1f22b5e92e40d8d5f97f02505021824823796767c1725c821b171b3ff6bf281d0123bf0b7e336f4d81b84bbf9362c6489f30b7de7c2037238c53003d6e00 SHA512 7c6815936e9a027d278a893e90e30f28a3d011ec83723c6500bee7ba0dddc5c96ae3cd75d7e16f7bbd2f9ee635fb64bdba6c2ba1df32761a6215be6eb3d5ec5c
diff --git a/www-client/opera-beta/opera-beta-83.0.4254.5.ebuild b/www-client/opera-beta/opera-beta-83.0.4254.5.ebuild
new file mode 100644
index 000000000000..d23934604a09
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-83.0.4254.5.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+ be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+ it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+ zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+ inherit rpm
+ OPERA_ARCHIVE_EXT="rpm"
+else
+ inherit unpacker
+ OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+ "https://download1.operacdn.com/pub/${PN}"
+ "https://download2.operacdn.com/pub/${PN}"
+ "https://download3.operacdn.com/pub/${PN}"
+ "https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+ MY_PN=${PN}-stable
+ SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+ MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="96.0.4655.7"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+ proprietary-codecs? (
+ mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+ )"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+ app-accessibility/at-spi2-atk:2
+ app-accessibility/at-spi2-core:2
+ dev-libs/atk
+ dev-libs/expat
+ dev-libs/glib:2
+ dev-libs/nspr
+ dev-libs/nss
+ gnome-base/gsettings-desktop-schemas
+ media-libs/alsa-lib
+ media-libs/mesa[gbm(+)]
+ net-misc/curl
+ net-print/cups
+ sys-apps/dbus
+ x11-libs/cairo
+ x11-libs/gdk-pixbuf
+ x11-libs/gtk+:3
+ x11-libs/libdrm
+ x11-libs/libxcb
+ x11-libs/libxkbcommon
+ x11-libs/libxshmfence
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXrandr
+ x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+ # Protect against people using autounmask overzealously
+ use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+ chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+ :
+}
+
+src_install() {
+ dodir /
+ cd "${ED}" || die
+ if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+ rpm_src_unpack "${A[0]}"
+ else
+ unpacker
+ fi
+
+ # move to /opt, bug #573052
+ mkdir -p "${OPERA_HOME%${PN}}"
+ if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+ mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+ else
+ mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+ fi
+ rm -r "usr/lib" || die
+
+ # disable auto update
+ rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+ if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+ rm "${OPERA_HOME}/setup_repo.sh" || die
+ else
+ rm -r "usr/share/lintian" || die
+
+ # fix docs
+ mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+ gzip -d usr/share/doc/${PF}/changelog.gz || die
+ fi
+
+ # fix desktop file
+ sed -i \
+ -e 's|^TargetEnvironment|X-&|g' \
+ usr/share/applications/${PN}.desktop || die
+
+ # remove unused language packs
+ pushd "${OPERA_HOME}/localization" > /dev/null || die
+ chromium_remove_language_paks
+ popd > /dev/null || die
+
+ # setup opera symlink
+ rm "usr/bin/${PN}" || die
+ dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+ # install proprietary codecs
+ rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+ if use proprietary-codecs; then
+ mv lib_extra "${OPERA_HOME}"
+ fi
+
+ # pax mark opera, bug #562038
+ pax-mark m "${OPERA_HOME}/opera"
+ # enable suid sandbox if requested
+ use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}