1 files changed, 64 insertions, 0 deletions
diff --git a/app-cdr/cuecue/cuecue-0.2.2-r5.ebuild b/app-cdr/cuecue/cuecue-0.2.2-r5.ebuild
new file mode 100644
index 000000000000..da05b944e010
--- /dev/null
+++ b/app-cdr/cuecue/cuecue-0.2.2-r5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Cuecue converts .cue + [.ogg|.flac|.wav|.mp3] to .cue + .bin"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# Enable one use flag by default, bug #254745
+IUSE="+flac mp3 +vorbis"
+REQUIRED_USE="|| ( flac mp3 vorbis )"
+
+DEPEND="
+	flac? ( media-libs/flac:= )
+	mp3? ( media-libs/libmad )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+"
+RDEPEND="
+	${DEPEND}
+"
+# We always need flac for AM_PATH_LIBFLAC if autoreconfing, bug #882447
+BDEPEND="media-libs/flac"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-flac113.diff # bug 157706
+	"${FILESDIR}"/${P}-namespace.patch
+	"${FILESDIR}"/${P}-unused.patch
+	"${FILESDIR}"/${P}-fno-common.patch
+	"${FILESDIR}"/${P}-configure.patch
+)
+
+src_prepare() {
+	default
+
+	# Clang 16
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable flac) \
+		$(use_enable mp3) \
+		$(use_enable vorbis ogg) \
+		--disable-libFLACtest \
+		--disable-oggtest \
+		--disable-vorbistest
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	insinto /usr/include
+	doins src/libcuecue/cuecue.h
+}