1 files changed, 57 insertions, 0 deletions
diff --git a/app-forensics/honggfuzz/honggfuzz-2.5-r1.ebuild b/app-forensics/honggfuzz/honggfuzz-2.5-r1.ebuild
new file mode 100644
index 000000000000..54fe2dc7889f
--- /dev/null
+++ b/app-forensics/honggfuzz/honggfuzz-2.5-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A general purpose fuzzer with feedback support"
+HOMEPAGE="https://honggfuzz.dev/"
+SRC_URI="https://github.com/google/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="clang"
+
+RDEPEND="
+	>=sys-libs/binutils-libs-2.29:=
+	sys-libs/libunwind:=
+	app-arch/xz-utils
+	clang? ( sys-libs/blocksruntime )
+"
+
+DEPEND="${RDEPEND}
+	elibc_musl? ( sys-libs/queue-standalone )"
+
+DOCS=(
+	CHANGELOG
+	COPYING
+	CONTRIBUTING.md
+	README.md
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.0-no-werror.patch
+	"${FILESDIR}"/${PN}-2.5_binutils239.patch
+)
+
+pkg_pretend() {
+	if tc-is-clang; then
+		use clang || die "${P}: to use clang enable USE=clang for ${P} (bug #729256)."
+	fi
+}
+
+src_prepare() {
+	default
+	tc-export AR CC
+	export CFLAGS
+	export LDFLAGS
+}
+
+src_install() {
+	dobin ${PN}
+	dobin hfuzz_cc/hfuzz-cc
+
+	einstalldocs
+}