summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-shells/fish/fish-2.3.1.ebuild')
-rw-r--r--app-shells/fish/fish-2.3.1.ebuild74
1 files changed, 74 insertions, 0 deletions
diff --git a/app-shells/fish/fish-2.3.1.ebuild b/app-shells/fish/fish-2.3.1.ebuild
new file mode 100644
index 000000000000..52deb65b8396
--- /dev/null
+++ b/app-shells/fish/fish-2.3.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit autotools
+
+DESCRIPTION="fish is the Friendly Interactive SHell"
+HOMEPAGE="http://fishshell.com/"
+SRC_URI="https://github.com/fish-shell/fish-shell/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="X"
+
+DEPEND="sys-libs/ncurses:0=
+ sys-devel/bc
+ sys-devel/gettext
+ X? ( x11-misc/xsel )"
+
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-shell-${PV}"
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ # Set things up for fish to be a default shell.
+ # It has to be in /bin in case /usr is unavailable.
+ # Also, all of its utilities have to be in /bin.
+ econf \
+ docdir="${EPREFIX}"/usr/share/doc/${PF} \
+ --bindir="${EPREFIX}"/bin
+}
+
+src_test() {
+ if has_version ~${CATEGORY}/${P} ; then
+ emake test
+ else
+ ewarn "The test suite only works when the package is already installed"
+ fi
+}
+
+pkg_postinst() {
+ elog "fish is now installed on your system."
+ elog "To run fish, type 'fish' in your terminal."
+ elog
+ elog "To use fish as your login shell:"
+ elog "* add the line '${EPREFIX}/bin/${PN}'"
+ elog "* to the file '${EPREFIX}/etc/shells'."
+ elog "* use the command 'chsh -s ${EPREFIX}/bin/${PN}'."
+ elog
+ elog "To set your colors, run 'fish_config'"
+ elog "To scan your man pages for completions, run 'fish_update_completions'"
+ elog "To autocomplete command suggestions press Ctrl + F or right arrow key."
+ elog
+ elog "Please add a \"BROWSER\" variable to ${PN}'s environment pointing to the"
+ elog "browser of your choice to get acces to ${PN}'s help system:"
+ elog " BROWSER=\"/usr/bin/firefox\""
+ elog
+ elog "In order to get lzma and xz support for man-page completion please"
+ elog "emerge one of the following packages:"
+ elog " dev-python/backports-lzma"
+ elog " >=dev-lang/python-3.3"
+ elog
+ elog "Have fun!"
+}