1 files changed, 51 insertions, 0 deletions
diff --git a/dev-util/dialog/dialog-1.2.20150528.ebuild b/dev-util/dialog/dialog-1.2.20150528.ebuild
new file mode 100644
index 000000000000..21ec10439328
--- /dev/null
+++ b/dev-util/dialog/dialog-1.2.20150528.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils multilib versionator
+
+MY_PV="$(get_version_component_range 1-2)-$(get_version_component_range 3)"
+S=${WORKDIR}/${PN}-${MY_PV}
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
+SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.2-r5[unicode?]
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	!minimal? ( sys-devel/libtool )
+	!<=sys-freebsd/freebsd-contrib-8.9999
+"
+
+src_prepare() {
+	sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
+	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-rpath-hack \
+		$(use_enable nls) \
+		$(use_with !minimal libtool) \
+		--with-libtool-opts=$(usex static-libs '' '-shared') \
+		--with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+	use minimal && default || emake DESTDIR="${D}" install-full
+
+	use examples && dodoc -r samples
+
+	dodoc CHANGES README
+
+	prune_libtool_files
+}