1 files changed, 71 insertions, 0 deletions
diff --git a/kde-apps/grantlee-editor/grantlee-editor-16.08.3.ebuild b/kde-apps/grantlee-editor/grantlee-editor-16.08.3.ebuild
new file mode 100644
index 000000000000..79a25f611b08
--- /dev/null
+++ b/kde-apps/grantlee-editor/grantlee-editor-16.08.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KMNAME="kdepim"
+MY_PN="grantleeeditor"
+inherit kde5
+
+DESCRIPTION="Utilities and tools to manage themes in KDE PIM applications"
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_kdeapps_dep akonadi-contacts)
+	$(add_kdeapps_dep kblog)
+	$(add_kdeapps_dep kcontacts)
+	$(add_kdeapps_dep kmime)
+	$(add_kdeapps_dep kpimtextedit)
+	$(add_kdeapps_dep libkdepim)
+	$(add_kdeapps_dep messagelib)
+	$(add_kdeapps_dep pimcommon)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwebengine 'widgets')
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}
+	!kde-apps/kaddressbook:4
+	!kde-apps/kdepim:5
+	!kde-apps/kdepim-common-libs:4
+	!kde-apps/kmail:4
+"
+
+if [[ ${KDE_BUILD_TYPE} = live ]] ; then
+	S="${WORKDIR}/${P}/${MY_PN}"
+else
+	S="${WORKDIR}/${KMNAME}-${PV}/${MY_PN}"
+fi
+
+src_prepare() {
+	# grantleeeditor subproject does not contain doc
+	# at least until properly split upstream
+	echo "add_subdirectory(doc)" >> CMakeLists.txt || die "Failed to add doc dir"
+
+	mkdir doc || die "Failed to create doc dir"
+	mv ../doc/contactthemeeditor doc || die "Failed to move handbook"
+	mv ../doc/headerthemeeditor doc || die "Failed to move handbook"
+	cat <<-EOF > doc/CMakeLists.txt
+add_subdirectory(contactthemeeditor)
+add_subdirectory(headerthemeeditor)
+EOF
+
+	kde5_src_prepare
+}