summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'kde-plasma/kde-gtk-config/kde-gtk-config-5.21.3.ebuild')
-rw-r--r--kde-plasma/kde-gtk-config/kde-gtk-config-5.21.3.ebuild57
1 files changed, 57 insertions, 0 deletions
diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.21.3.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.21.3.ebuild
new file mode 100644
index 000000000000..beb08dab9bc0
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.21.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.78.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="GTK2 and GTK3 configurator for KDE Plasma"
+HOMEPAGE="https://invent.kde.org/plasma/kde-gtk-config"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="
+ dev-lang/sassc
+"
+DEPEND="
+ dev-cpp/glibmm:2
+ dev-libs/glib:2
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtsvg-${QTMIN}:5
+ gnome-base/gsettings-desktop-schemas
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/kguiaddons-${KFMIN}:5
+ >=kde-plasma/kdecoration-${PVCUT}:5
+ x11-libs/gtk+:2
+ x11-libs/gtk+:3
+"
+RDEPEND="${DEPEND}
+ >=kde-plasma/kde-cli-tools-${PVCUT}:5
+ x11-misc/xsettingsd
+"
+
+src_configure() {
+ local mycmakeargs=(
+ -DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ ecm_pkg_postinst
+ elog "If you notice missing icons in your GTK applications, you may have to install"
+ elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+ elog "for example."
+}