summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'kde-plasma/kdeplasma-addons/kdeplasma-addons-5.20.4.ebuild')
-rw-r--r--kde-plasma/kdeplasma-addons/kdeplasma-addons-5.20.4.ebuild75
1 files changed, 75 insertions, 0 deletions
diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.20.4.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.20.4.ebuild
new file mode 100644
index 000000000000..3f921c96d88c
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.20.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.74.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Extra Plasma applets and engines"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="comic share webengine"
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/karchive-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcmutils-${KFMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:5
+ >=kde-frameworks/kholidays-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kiconthemes-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/knewstuff-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/kpackage-${KFMIN}:5
+ >=kde-frameworks/krunner-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/kunitconversion-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kwindowsystem-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/plasma-${KFMIN}:5
+ >=kde-frameworks/sonnet-${KFMIN}:5
+ comic? ( >=kde-frameworks/kross-${KFMIN}:5 )
+ share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+ webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-plasma/plasma-workspace-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.19.3-kross-optional.patch" ) # downstream patch
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package comic KF5Kross)
+ $(cmake_use_find_package share KF5Purpose)
+ $(cmake_use_find_package webengine Qt5WebEngine)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ elog "Optional dependencies:"
+ optfeature "Disk quota applet" sys-fs/quota
+ fi
+ ecm_pkg_postinst
+}