1 files changed, 45 insertions, 0 deletions
diff --git a/media-libs/sdl-net/sdl-net-1.2.8-r1.ebuild b/media-libs/sdl-net/sdl-net-1.2.8-r1.ebuild
new file mode 100644
index 000000000000..b6ccbac7ceb9
--- /dev/null
+++ b/media-libs/sdl-net/sdl-net-1.2.8-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit multilib-minimal
+
+MY_P=${P/sdl-/SDL_}
+DESCRIPTION="Simple Direct Media Layer Network Support Library"
+HOMEPAGE="http://www.libsdl.org/projects/SDL_net/index.html"
+SRC_URI="http://www.libsdl.org/projects/SDL_net/release/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	abi_x86_32? (
+		!app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
+		!<=app-emulation/emul-linux-x86-sdl-20140406
+	)
+	>=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-dependency-tracking \
+		--disable-gui \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	dodoc CHANGES README
+	if ! use static-libs ; then
+		find "${D}" -type f -name '*.la' -exec rm {} + \
+			|| die "la removal failed"
+	fi
+}