1 files changed, 50 insertions, 0 deletions
diff --git a/net-dns/openresolv/openresolv-3.7.2.ebuild b/net-dns/openresolv/openresolv-3.7.2.ebuild
new file mode 100644
index 000000000000..1af747f9d1b7
--- /dev/null
+++ b/net-dns/openresolv/openresolv-3.7.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="A framework for managing DNS information"
+HOMEPAGE="http://roy.marples.name/projects/openresolv"
+SRC_URI="http://roy.marples.name/downloads/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="selinux"
+
+DEPEND="!net-dns/resolvconf-gentoo
+	!<net-dns/dnsmasq-2.40-r1"
+RDEPEND="selinux? ( sec-policy/selinux-resolvconf )"
+
+src_configure() {
+	econf \
+		--prefix= \
+		--rundir=/var/run \
+		--libexecdir=/lib/resolvconf \
+		--restartcmd="/lib/resolvconf/helpers/restartcmd \1"
+}
+
+src_install() {
+	default
+	exeinto /lib/resolvconf/helpers
+	doexe "${FILESDIR}"/restartcmd
+}
+
+pkg_config() {
+	if [ "${ROOT}" != "/" ]; then
+		eerror "We cannot configure unless \$ROOT=/"
+		return 1
+	fi
+
+	if [ -n "$(resolvconf -l)" ]; then
+		einfo "${PN} already has DNS information"
+	else
+		ebegin "Copying /etc/resolv.conf to resolvconf -a dummy"
+		resolvconf -a dummy </etc/resolv.conf
+		eend $? || return $?
+		einfo "The dummy interface will disappear when you next reboot"
+	fi
+}