1 files changed, 46 insertions, 0 deletions
diff --git a/sci-biology/abyss/abyss-1.3.4.ebuild b/sci-biology/abyss/abyss-1.3.4.ebuild
new file mode 100644
index 000000000000..e230da8847ff
--- /dev/null
+++ b/sci-biology/abyss/abyss-1.3.4.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils
+
+DESCRIPTION="Assembly By Short Sequences - a de novo, parallel, paired-end sequence assembler"
+HOMEPAGE="http://www.bcgsc.ca/platform/bioinfo/software/abyss/"
+SRC_URI="http://www.bcgsc.ca/downloads/abyss/${P}.tar.gz"
+
+LICENSE="abyss"
+SLOT="0"
+IUSE="+mpi openmp"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-cpp/sparsehash
+	mpi? ( virtual/mpi )"
+RDEPEND="${DEPEND}"
+
+# todo: --enable-maxk=N configure option
+# todo: fix automagic mpi toggling
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-4.7.patch
+	"${FILESDIR}"/${PN}-1.3.3-ac_prog_ar.patch
+	)
+
+src_prepare() {
+	tc-export AR
+	sed -i -e "s/-Werror//" configure.ac || die #365195
+	sed -i -e "/dist_pkgdoc_DATA/d" Makefile.am || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--docdir="${EPREFIX}/usr/share/doc/${PF}"
+		$(use_enable openmp)
+	)
+	autotools-utils_src_configure
+}