1 files changed, 59 insertions, 0 deletions
diff --git a/sys-apps/accountsservice/accountsservice-0.6.45.ebuild b/sys-apps/accountsservice/accountsservice-0.6.45.ebuild
new file mode 100644
index 000000000000..fb05d15bebcc
--- /dev/null
+++ b/sys-apps/accountsservice/accountsservice-0.6.45.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome2 systemd
+
+DESCRIPTION="D-Bus interfaces for querying and manipulating user account information"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/AccountsService/"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="doc elogind +introspection selinux systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+CDEPEND="
+	>=dev-libs/glib-2.37.3:2
+	sys-auth/polkit
+	elogind? ( >=sys-auth/elogind-229.4 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	systemd? ( >=sys-apps/systemd-186:0= )
+	!systemd? ( !elogind? ( sys-auth/consolekit ) )
+"
+DEPEND="${CDEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.15
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto )
+"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-accountsd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.35-gentoo-system-users.patch
+	"${FILESDIR}"/${PN}-0.6.43-elogind.patch
+)
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-more-warnings \
+		--localstatedir="${EPREFIX}"/var \
+		--enable-admin-group="wheel" \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)" \
+		$(use_enable doc docbook-docs) \
+		$(use_enable elogind) \
+		$(use_enable introspection) \
+		$(use_enable systemd)
+}