1 files changed, 58 insertions, 0 deletions
diff --git a/sys-apps/checkpolicy/checkpolicy-9999.ebuild b/sys-apps/checkpolicy/checkpolicy-9999.ebuild
new file mode 100644
index 000000000000..0d877e0cc8fb
--- /dev/null
+++ b/sys-apps/checkpolicy/checkpolicy-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit toolchain-funcs eutils
+
+MY_P="${P//_/-}"
+MY_RELEASEDATE="20150202"
+
+SEPOL_VER="${PV}"
+SEMNG_VER="${PV}"
+
+DESCRIPTION="SELinux policy compiler"
+HOMEPAGE="http://userspace.selinuxproject.org"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/SELinuxProject/selinux.git"
+	S="${WORKDIR}/${MY_P}/${PN}"
+else
+	SRC_URI="https://raw.githubusercontent.com/wiki/SELinuxProject/selinux/files/releases/${MY_RELEASEDATE}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug"
+
+DEPEND=">=sys-libs/libsepol-${SEPOL_VER}
+	>=sys-libs/libsemanage-${SEMNG_VER}
+	sys-devel/flex
+	sys-devel/bison"
+
+RDEPEND=">=sys-libs/libsemanage-${SEMNG_VER}"
+
+src_prepare() {
+	epatch_user
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" YACC="bison -y" LIBDIR="\$(PREFIX)/$(get_libdir)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use debug; then
+		dobin "${S}/test/dismod"
+		dobin "${S}/test/dispol"
+	fi
+}
+
+pkg_postinst() {
+	einfo "This checkpolicy can compile version `checkpolicy -V |cut -f 1 -d ' '` policy."
+}