summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'x11-terms/gnome-terminal/gnome-terminal-3.23.90.ebuild')
-rw-r--r--x11-terms/gnome-terminal/gnome-terminal-3.23.90.ebuild73
1 files changed, 0 insertions, 73 deletions
diff --git a/x11-terms/gnome-terminal/gnome-terminal-3.23.90.ebuild b/x11-terms/gnome-terminal/gnome-terminal-3.23.90.ebuild
deleted file mode 100644
index 9991d0009b29..000000000000
--- a/x11-terms/gnome-terminal/gnome-terminal-3.23.90.ebuild
+++ /dev/null
@@ -1,73 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-GNOME2_LA_PUNT="yes"
-
-inherit autotools gnome2 readme.gentoo-r1
-
-DESCRIPTION="The Gnome Terminal"
-HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/"
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="debug +gnome-shell +nautilus vanilla"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
-
-# FIXME: automagic dependency on gtk+[X], just transitive but needs proper control
-RDEPEND="
- >=dev-libs/glib-2.42:2[dbus]
- >=x11-libs/gtk+-3.20:3[X]
- >=x11-libs/vte-0.47.90:2.91
- >=dev-libs/libpcre2-10
- >=gnome-base/dconf-0.14
- >=gnome-base/gsettings-desktop-schemas-0.1.0
- sys-apps/util-linux
- gnome-shell? ( gnome-base/gnome-shell )
- nautilus? ( >=gnome-base/nautilus-3 )
-"
-# itstool required for help/* with non-en LINGUAS, see bug #549358
-# xmllint required for glib-compile-resources, see bug #549304
-DEPEND="${RDEPEND}
- app-text/yelp-tools
- dev-libs/libxml2
- dev-util/gdbus-codegen
- >=dev-util/intltool-0.50
- sys-devel/gettext
- virtual/pkgconfig
-"
-
-DOC_CONTENTS="To get previous working directory inherited in new opened
- tab you will need to add the following line to your ~/.bashrc:\n
- . /etc/profile.d/vte.sh"
-
-src_prepare() {
- if ! use vanilla; then
- # OpenSuSE patches, https://bugzilla.gnome.org/show_bug.cgi?id=695371
- # http://pkgs.fedoraproject.org/cgit/rpms/gnome-terminal.git/tree/gnome-terminal-transparency-notify.patch (first 3 parts)
- eapply "${FILESDIR}"/${PN}-3.22.0-transparency.patch
- eautoreconf
- fi
- gnome2_src_prepare
-}
-
-src_configure() {
- gnome2_src_configure \
- --disable-static \
- --disable-migration \
- $(use_enable debug) \
- $(use_enable gnome-shell search-provider) \
- $(use_with nautilus nautilus-extension) \
- VALAC=$(type -P true)
-}
-
-src_install() {
- DOCS="AUTHORS ChangeLog HACKING NEWS"
- gnome2_src_install
- readme.gentoo_create_doc
-}
-
-pkg_postinst() {
- gnome2_pkg_postinst
- readme.gentoo_print_elog
-}