From 04a08756c739c1607f47a75fb15c0875ba48f178 Mon Sep 17 00:00:00 2001
From: Zetok Zalbavar <zetok@openmailbox.org>
Date: Sat, 17 Dec 2016 01:31:32 +0000
Subject: net-libs/tox: add ebuild for the v0.1.1 release

Closes: https://github.com/gentoo/gentoo/pull/3140
Package-Manager: portage-2.3.0
---
 net-libs/tox/Manifest         |  1 +
 net-libs/tox/tox-0.1.1.ebuild | 77 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)
 create mode 100644 net-libs/tox/tox-0.1.1.ebuild

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index 69be34aef8d3..a1cf88a9242b 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1 +1,2 @@
+DIST tox-0.1.1.tar.gz 416532 SHA256 c3a6329731a35c1e9cd8ad204407ddbc408f325056de2b1baa1fc44bc8bfcb37 SHA512 5bdaf047594e943f854fda0f0265167e0dccf05fedfec6b4d9b628b242de23f9dd9b870bbdcca4cb02f9742fa2472e4c7e1047370732cb2ee529467f15e81fc1 WHIRLPOOL 32ee00f6eaf98473ce3de080ba36185da2c225b2037574b55060a12e88876fb1f7df492614fbbb493ba85a44a319f3e0c254c0daec1e8cc18472ba075834039f
 DIST tox-0_pre20160904.tar.gz 395495 SHA256 2d4a0d096bdb81b12b10551765fb9f87270e170f10f387f700b3def68cb6c35c SHA512 c0da52ac908141e97e96510a05431cbfb4b9aae81faf4c136c95e21b90a23e3bbe6db88303e48c0f4f3c74ca954229787564b7aa41bfb462afb0d8f8430cdaa1 WHIRLPOOL abd3f61784fac93d983e453515d1e8bc87f7d76651a53ce6f566a277d7ec7c1e03294d95781364ce9ab30f2698c6f5cd552bfa4888f8d5d0d315daf038980c63
diff --git a/net-libs/tox/tox-0.1.1.ebuild b/net-libs/tox/tox-0.1.1.ebuild
new file mode 100644
index 000000000000..6e8fafbdec86
--- /dev/null
+++ b/net-libs/tox/tox-0.1.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools systemd user
+
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.1"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon log-debug log-error log-info log-trace log-warn +no-log ntox static-libs test"
+
+REQUIRED_USE="^^ ( no-log log-trace log-debug log-info log-warn log-error )"
+
+RDEPEND="
+	av? ( media-libs/libvpx:=
+		media-libs/opus )
+	daemon? ( dev-libs/libconfig )
+	ntox? ( sys-libs/ncurses:0= )
+	>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/c-toxcore-${PV}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(usex log-trace "--enable-logging --with-log-level=TRACE" "") \
+		$(usex log-debug "--enable-logging --with-log-level=DEBUG" "") \
+		$(usex log-info "--enable-logging --with-log-level=INFO" "") \
+		$(usex log-warn "--enable-logging --with-log-level=WARNING" "") \
+		$(usex log-error "--enable-logging --with-log-level=ERROR" "") \
+		$(use_enable av) \
+		$(use_enable test tests) \
+		$(use_enable ntox) \
+		$(use_enable daemon) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if use daemon; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 -1 ${PN}
+		if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
+			ewarn "Backwards compatability with the bootstrap daemon might have been"
+			ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+			ewarn "    ${EROOT%/}/var/lib/tox-dht-bootstrap/key"
+			ewarn "    ${EROOT%/}/etc/tox-bootstrapd.conf"
+			ewarn "    ${EROOT%/}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+			ewarn "Then just re-emerge net-libs/tox"
+		fi
+	fi
+}
-- 
cgit v1.2.3-65-gdbad