From 54defbd269995d139b5f27647a52b4c99e95964d Mon Sep 17 00:00:00 2001
From: Petr Vaněk <arkamar@atlas.cz>
Date: Mon, 9 Mar 2020 10:08:43 +0100
Subject: dev-libs/hyperscan: correct python dependencies
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Python is build time dependency only. It works perfectly with python3
and there is no need to depend on Python2.

Closes: https://bugs.gentoo.org/710218
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-libs/hyperscan/hyperscan-5.2.1-r1.ebuild | 44 ++++++++++++++++++++++++++++
 dev-libs/hyperscan/hyperscan-5.2.1.ebuild    | 42 --------------------------
 2 files changed, 44 insertions(+), 42 deletions(-)
 create mode 100644 dev-libs/hyperscan/hyperscan-5.2.1-r1.ebuild
 delete mode 100644 dev-libs/hyperscan/hyperscan-5.2.1.ebuild

diff --git a/dev-libs/hyperscan/hyperscan-5.2.1-r1.ebuild b/dev-libs/hyperscan/hyperscan-5.2.1-r1.ebuild
new file mode 100644
index 000000000000..aa7ab14e7067
--- /dev/null
+++ b/dev-libs/hyperscan/hyperscan-5.2.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit cmake flag-o-matic python-any-r1
+
+DESCRIPTION="High-performance regular expression matching library"
+SRC_URI="https://github.com/intel/hyperscan/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+HOMEPAGE="https://www.hyperscan.io/ https://github.com/intel/hyperscan"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+cpu_flags_x86_ssse3 static-libs"
+
+RDEPEND="dev-libs/boost"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ragel
+"
+
+REQUIRED_USE="cpu_flags_x86_ssse3"
+
+src_prepare() {
+	# upstream workaround
+	append-cxxflags -Wno-redundant-move
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=$(usex static-libs OFF ON)
+		-DBUILD_STATIC_AND_SHARED=$(usex static-libs ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unit-hyperscan || die
+}
diff --git a/dev-libs/hyperscan/hyperscan-5.2.1.ebuild b/dev-libs/hyperscan/hyperscan-5.2.1.ebuild
deleted file mode 100644
index 8789fd913c71..000000000000
--- a/dev-libs/hyperscan/hyperscan-5.2.1.ebuild
+++ /dev/null
@@ -1,42 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python2_7 )
-
-inherit cmake python-r1 flag-o-matic
-
-DESCRIPTION="High-performance regular expression matching library"
-SRC_URI="https://github.com/intel/hyperscan/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-HOMEPAGE="https://www.hyperscan.io/ https://github.com/intel/hyperscan"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="+cpu_flags_x86_ssse3 static-libs"
-
-RDEPEND="${PYTHON_DEPS}
-	dev-libs/boost"
-DEPEND="${RDEPEND}"
-BDEPEND="dev-util/ragel"
-
-REQUIRED_USE="cpu_flags_x86_ssse3 ${PYTHON_REQUIRED_USE}"
-
-src_prepare() {
-	# upstream workaround
-	append-cxxflags -Wno-redundant-move
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=$(usex static-libs OFF ON)
-		-DBUILD_STATIC_AND_SHARED=$(usex static-libs ON OFF)
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	"${BUILD_DIR}"/bin/unit-hyperscan || die
-}
-- 
cgit v1.2.3-18-g5258