From 98d377e7f4358ae609320367237e137da8355984 Mon Sep 17 00:00:00 2001
From: Nick Sarnie <sarnex@gentoo.org>
Date: Wed, 8 Dec 2021 19:32:31 -0500
Subject: media-libs/vulkan-layers: Fix header install path

Closes: https://bugs.gentoo.org/827494
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>
---
 .../vulkan-layers/vulkan-layers-1.2.198-r1.ebuild  | 57 ++++++++++++++++++++++
 media-libs/vulkan-layers/vulkan-layers-9999.ebuild |  2 +-
 2 files changed, 58 insertions(+), 1 deletion(-)
 create mode 100644 media-libs/vulkan-layers/vulkan-layers-1.2.198-r1.ebuild

diff --git a/media-libs/vulkan-layers/vulkan-layers-1.2.198-r1.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.2.198-r1.ebuild
new file mode 100644
index 000000000000..8620262391de
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.2.198-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-ValidationLayers
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+RDEPEND="~dev-util/spirv-tools-${PV}:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-cpp/robin-hood-hashing
+	~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}]
+	~dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_LAYER_SUPPORT_FILES=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/"
+		-DSPIRV_HEADERS_INSTALL_DIR="${ESYSROOT}/usr/include/spirv"
+	)
+	cmake_src_configure
+}
diff --git a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
index ecfbe9b339e3..5beaf4f6dc7a 100644
--- a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
+++ b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
@@ -50,7 +50,7 @@ multilib_src_configure() {
 		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
 		-DBUILD_TESTS=OFF
 		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
-		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/vulkan/"
+		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/"
 		-DSPIRV_HEADERS_INSTALL_DIR="${ESYSROOT}/usr/include/spirv"
 	)
 	cmake_src_configure
-- 
cgit v1.2.3-65-gdbad