From b2e061b9039f5ab989ecef7b4b425e1a17915170 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Sun, 17 Jun 2018 07:15:02 -0400
Subject: dev-python/pycairo: version bump to 1.17.0

---
 dev-python/pycairo/Manifest              |  1 +
 dev-python/pycairo/pycairo-1.17.0.ebuild | 47 ++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 dev-python/pycairo/pycairo-1.17.0.ebuild

diff --git a/dev-python/pycairo/Manifest b/dev-python/pycairo/Manifest
index 137e3a16855b..f9e41f94403f 100644
--- a/dev-python/pycairo/Manifest
+++ b/dev-python/pycairo/Manifest
@@ -1 +1,2 @@
 DIST pycairo-1.16.3.tar.gz 188610 BLAKE2B 71034891bae636e23379a3fdc49c9163cff61183fe46c4027bbad3206e72255e60081dbc3cb02808d5c3840b618f6c12f8106ca5a08ddb226a65917ba2da390c SHA512 d60978f85eb0430f2038b0e7d0bce23602e8c180a7611eea424fd8bc3cdd8ce249af364abd0e77ab3b7ab439761721cba5c2398f51af2a89add3fb7fda8aa5db
+DIST pycairo-1.17.0.tar.gz 192182 BLAKE2B b7a4db8258b03b89878fca6b5e27bb9037b74b1792ded23edfe38a0aa5e9ba5003bbac2c8623a6ace8033960c3199b307dcb689650e21ba2df0d81a36a71b6cf SHA512 c073f04d92c9a577f7dcea8d46335751ebd896a65e682e99e4453877d8ba2cadad4437f4ceb1ce8c05eb87d5757a2bd78ac2549e63e38720f4c9276e6f70bdd5
diff --git a/dev-python/pycairo/pycairo-1.17.0.ebuild b/dev-python/pycairo/pycairo-1.17.0.ebuild
new file mode 100644
index 000000000000..8c80861142db
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.17.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=x11-libs/cairo-1.13.1[svg]
+"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && emake -C docs
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/. )
+
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad