From ca959af4ffe4122207405b15a039ea8d91652967 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Sat, 15 Feb 2020 10:00:05 -0800
Subject: app-admin/metalog-20200113: Revbump, fix name of consolelog (bug
 709726)

Closes: https://bugs.gentoo.org/709726
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 app-admin/metalog/metalog-20200113-r1.ebuild | 65 ++++++++++++++++++++++++++++
 app-admin/metalog/metalog-20200113.ebuild    | 65 ----------------------------
 2 files changed, 65 insertions(+), 65 deletions(-)
 create mode 100644 app-admin/metalog/metalog-20200113-r1.ebuild
 delete mode 100644 app-admin/metalog/metalog-20200113.ebuild

(limited to 'app-admin/metalog')

diff --git a/app-admin/metalog/metalog-20200113-r1.ebuild b/app-admin/metalog/metalog-20200113-r1.ebuild
new file mode 100644
index 000000000000..0810553ec43d
--- /dev/null
+++ b/app-admin/metalog/metalog-20200113-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools systemd
+
+DESCRIPTION="A highly configurable replacement for syslogd/klogd"
+HOMEPAGE="https://github.com/hvisage/metalog"
+SRC_URI="https://github.com/hvisage/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin"
+IUSE="unicode"
+
+RDEPEND=">=dev-libs/libpcre-3.4"
+DEPEND="${RDEPEND}
+	sys-devel/autoconf-archive
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}-${P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9-metalog-conf.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with unicode)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README NEWS metalog.conf
+
+	into /
+	newsbin "${FILESDIR}"/consolelog.sh-r1 consolelog.sh
+
+	newinitd "${FILESDIR}"/metalog.initd-r1 metalog
+	newconfd "${FILESDIR}"/metalog.confd metalog
+	systemd_newunit "${FILESDIR}/${PN}.service-r1" "${PN}.service"
+}
+
+pkg_preinst() {
+	if [[ -d "${ROOT}"/etc/metalog && ! -e "${ROOT}"/etc/metalog.conf ]] ; then
+		mv -f "${ROOT}"/etc/metalog/metalog.conf "${ROOT}"/etc/metalog.conf
+		rmdir "${ROOT}"/etc/metalog
+		export MOVED_METALOG_CONF=true
+	else
+		export MOVED_METALOG_CONF=false
+	fi
+}
+
+pkg_postinst() {
+	if ${MOVED_METALOG_CONF} ; then
+		ewarn "The default metalog.conf file has been moved"
+		ewarn "from /etc/metalog/metalog.conf to just"
+		ewarn "/etc/metalog.conf.  If you had a standard"
+		ewarn "setup, the file has been moved for you."
+	fi
+}
diff --git a/app-admin/metalog/metalog-20200113.ebuild b/app-admin/metalog/metalog-20200113.ebuild
deleted file mode 100644
index dfac2aa83578..000000000000
--- a/app-admin/metalog/metalog-20200113.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-inherit autotools systemd
-
-DESCRIPTION="A highly configurable replacement for syslogd/klogd"
-HOMEPAGE="https://github.com/hvisage/metalog"
-SRC_URI="https://github.com/hvisage/${PN}/archive/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin"
-IUSE="unicode"
-
-RDEPEND=">=dev-libs/libpcre-3.4"
-DEPEND="${RDEPEND}
-	sys-devel/autoconf-archive
-	virtual/pkgconfig"
-
-S="${WORKDIR}/${PN}-${P}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.9-metalog-conf.patch
-)
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	econf $(use_with unicode)
-}
-
-src_install() {
-	emake DESTDIR="${D}" install
-	dodoc AUTHORS ChangeLog README NEWS metalog.conf
-
-	into /
-	dosbin "${FILESDIR}"/consolelog.sh-r1
-
-	newinitd "${FILESDIR}"/metalog.initd-r1 metalog
-	newconfd "${FILESDIR}"/metalog.confd metalog
-	systemd_newunit "${FILESDIR}/${PN}.service-r1" "${PN}.service"
-}
-
-pkg_preinst() {
-	if [[ -d "${ROOT}"/etc/metalog && ! -e "${ROOT}"/etc/metalog.conf ]] ; then
-		mv -f "${ROOT}"/etc/metalog/metalog.conf "${ROOT}"/etc/metalog.conf
-		rmdir "${ROOT}"/etc/metalog
-		export MOVED_METALOG_CONF=true
-	else
-		export MOVED_METALOG_CONF=false
-	fi
-}
-
-pkg_postinst() {
-	if ${MOVED_METALOG_CONF} ; then
-		ewarn "The default metalog.conf file has been moved"
-		ewarn "from /etc/metalog/metalog.conf to just"
-		ewarn "/etc/metalog.conf.  If you had a standard"
-		ewarn "setup, the file has been moved for you."
-	fi
-}
-- 
cgit v1.2.3-65-gdbad