From 311f61f63e91aa555444c30fecd9530be54ec3db Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Mon, 27 Dec 2021 23:54:18 +0200
Subject: app-crypt/libsecret: remove old

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 app-crypt/libsecret/libsecret-0.20.4.ebuild | 90 -----------------------------
 1 file changed, 90 deletions(-)
 delete mode 100644 app-crypt/libsecret/libsecret-0.20.4.ebuild

(limited to 'app-crypt')

diff --git a/app-crypt/libsecret/libsecret-0.20.4.ebuild b/app-crypt/libsecret/libsecret-0.20.4.ebuild
deleted file mode 100644
index 5db7cd230147..000000000000
--- a/app-crypt/libsecret/libsecret-0.20.4.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{7..9} )
-VALA_USE_DEPEND=vapigen
-
-inherit gnome2 meson-multilib python-any-r1 vala virtualx
-
-DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
-HOMEPAGE="https://wiki.gnome.org/Projects/Libsecret"
-
-LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
-SLOT="0"
-
-IUSE="+crypt gtk-doc +introspection test +vala"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	vala? ( introspection )
-	gtk-doc? ( crypt )
-"
-
-KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
-
-DEPEND="
-	>=dev-libs/glib-2.44:2[${MULTILIB_USEDEP}]
-	crypt? ( >=dev-libs/libgcrypt-1.2.2:0=[${MULTILIB_USEDEP}] )
-	introspection? ( >=dev-libs/gobject-introspection-1.29:= )
-"
-RDEPEND="${DEPEND}"
-# gnome-keyring needed at runtime as explained at https://bugs.gentoo.org/475182#c2
-PDEPEND=">=gnome-base/gnome-keyring-3" # to avoid circular dep (bug #547456)
-BDEPEND="
-	dev-libs/libxslt
-	dev-util/gdbus-codegen
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-	test? (
-		$(python_gen_any_dep '
-			dev-python/mock[${PYTHON_USEDEP}]
-			dev-python/dbus-python[${PYTHON_USEDEP}]
-			introspection? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )')
-		introspection? ( >=dev-libs/gjs-1.32 )
-	)
-	vala? ( $(vala_depend) )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-meson-build-test-vala-unstable-with-DSECRET_WITH_UNS.patch
-)
-
-python_check_deps() {
-	if use introspection; then
-		has_version -b "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
-	fi
-	has_version -b "dev-python/mock[${PYTHON_USEDEP}]" &&
-	has_version -b "dev-python/dbus-python[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	use vala && vala_src_prepare
-	default
-
-	# Remove @filename@ from the header template that would otherwise cause
-	# differences dependent on the ABI
-	sed -e '/enumerations from "@filename@"/d' \
-		-i libsecret/secret-enum-types.h.template || die
-}
-
-multilib_src_configure() {
-	local emesonargs=(
-		$(meson_use crypt gcrypt)
-
-		# Don't build docs multiple times
-		$(meson_native_true manpage)
-		$(meson_native_use_bool gtk-doc gtk_doc)
-
-		$(meson_native_use_bool introspection)
-		$(meson_native_use_bool vala vapi)
-	)
-	meson_src_configure
-}
-
-multilib_src_test() {
-	virtx meson_src_test
-}
-- 
cgit v1.2.3-65-gdbad