From 346896ab21cef4b55236d80c4b41f03fb3006d0a Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Fri, 5 Jan 2018 23:31:38 +1100
Subject: dev-games/tiled: version bump 1.1.0

Package-Manager: Portage-2.3.14, Repoman-2.3.6
---
 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.1.0.ebuild | 63 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 dev-games/tiled/tiled-1.1.0.ebuild

(limited to 'dev-games')

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 0eb1a72e2521..c432218c15e5 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.0.3.tar.gz 6601791 BLAKE2B 86bca36994b8596931b68dace6db61443bfa488444d06d7bae616a1c095da2d8fd476fd7a466d6b7e95b2291a977e4893125fd09091e96733973bfbc5f66a651 SHA512 4f3c97a91794f86f04965a2332e04f51bc588f7bcfef402edb1092c4e58bb6ace9c90ea522a5fa15a46ca39c8249f62818b80be6d65c11a8d41092ead31cd4f7
+DIST tiled-1.1.0.tar.gz 15963801 BLAKE2B 69cba29e2bc501829636afae21cc02a48157d735620b8a04d52f0d73bb787cf8bcea1eba0c2da6a55d55dad70214ce42ac5fbd67529add07416d0702044345ce SHA512 8948a897636005bb837a922dca7cdeb8049983e11101d59e0f93255a88595bc64f1eca66a4737d3ec031ee222233e2edbd43d124d2f406698898bae4ee5f1bc1
diff --git a/dev-games/tiled/tiled-1.1.0.ebuild b/dev-games/tiled/tiled-1.1.0.ebuild
new file mode 100644
index 000000000000..518492b3f37a
--- /dev/null
+++ b/dev-games/tiled/tiled-1.1.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="http://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.7:5
+	>=dev-qt/qtgui-5.7:5
+	>=dev-qt/qtnetwork-5.7:5
+	>=dev-qt/qtwidgets-5.7:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3-65-gdbad