From 5466d202f324cb1e3d3a1f5fd966a13085063c5c Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Mon, 18 Mar 2019 15:07:28 +0200
Subject: dev-libs/gobject-introspection: bump to 1.58.3

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 dev-libs/gobject-introspection/Manifest            |  1 +
 .../gobject-introspection-1.58.3.ebuild            | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)
 create mode 100644 dev-libs/gobject-introspection/gobject-introspection-1.58.3.ebuild

(limited to 'dev-libs/gobject-introspection')

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index 4b70198648d9..14e60bd688bd 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1 +1,2 @@
 DIST gobject-introspection-1.56.1.tar.xz 1397812 BLAKE2B 070597f3bd6e4e58d1ae1964cf6e8d7881daa68aeeddc5e9b64bc410fad6d435f2041171f4dfc2a6b477d39f2d7e9181b9917d1244fcb45b3a37491726381649 SHA512 2bfcd45b8c5ad68a3f6550c2f80a6804db0e1a72ffaf4fdd3cec3d8acc23e79ad14bb5bf612fe26fc896691839ab19ca8dd1c9994db14d730e56fa79df9d973d
+DIST gobject-introspection-1.58.3.tar.xz 1378068 BLAKE2B 3ae0328892da30aeefcfb8f6d343312d4967345cc202ef137f29690fbd7a35fa9310f87b134fbdfd4fd753b68b47203cd306689d9892eccf17e303d1e7bcccd4 SHA512 0811cd08e224975b3aa55ae89d648fc65f3105cae8a077a5671593d84743b1db28e9fbffe53fc86a2b3e82ea98c35f3daae033d3df07c7020cc3bf8b5d94f796
diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.58.3.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.58.3.ebuild
new file mode 100644
index 000000000000..7f814af85a82
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.58.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="cairo doctool test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	test? ( cairo )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+# We force glib and g-i to be in sync by this way as explained in bug #518424
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.58.0:2
+	doctool? ( dev-python/mako[${PYTHON_USEDEP}]
+		dev-python/markdown[${PYTHON_USEDEP}] )
+	virtual/libffi:=
+	virtual/pkgconfig
+	!<dev-lang/vala-0.20.0
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.19
+	sys-devel/bison
+	sys-devel/flex
+	test? ( x11-libs/cairo[glib] )
+" # autoreconf needs autoconf-archive
+# PDEPEND to avoid circular dependencies, bug #391213; but needed for tests, thus test DEPEND as well
+PDEPEND="cairo? ( x11-libs/cairo[glib] )"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if ! has_version "x11-libs/cairo[glib]"; then
+		# Bug #391213: enable cairo-gobject support even if it's not installed
+		# We only PDEPEND on cairo to avoid circular dependencies
+		export CAIRO_LIBS="-lcairo -lcairo-gobject"
+		export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
+	fi
+
+	# To prevent crosscompiling problems, bug #414105
+	gnome2_src_configure \
+		--disable-static \
+		CC="$(tc-getCC)" \
+		YACC="$(type -p yacc)" \
+		$(use_with cairo) \
+		$(use_enable doctool)
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"usr/share/aclocal/introspection.m4 \
+		"${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"usr/share/aclocal || die
+}
-- 
cgit v1.2.3-65-gdbad