From 0894a9ed3b93862ab541bc6525eb5abd4d5294f7 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 14 Feb 2018 14:16:06 +0100
Subject: dev-libs/keybinder: Bump to EAPI=6

---
 dev-libs/keybinder/keybinder-0.3.1-r201.ebuild | 50 ++++++++++++++++++++++++++
 dev-libs/keybinder/keybinder-0.3.2-r300.ebuild | 13 ++++---
 2 files changed, 56 insertions(+), 7 deletions(-)
 create mode 100644 dev-libs/keybinder/keybinder-0.3.1-r201.ebuild

(limited to 'dev-libs/keybinder')

diff --git a/dev-libs/keybinder/keybinder-0.3.1-r201.ebuild b/dev-libs/keybinder/keybinder-0.3.1-r201.ebuild
new file mode 100644
index 000000000000..4557421f67e1
--- /dev/null
+++ b/dev-libs/keybinder/keybinder-0.3.1-r201.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-single-r1
+
+DESCRIPTION="A library for registering global keyboard shortcuts"
+HOMEPAGE="https://github.com/engla/keybinder"
+SRC_URI="https://github.com/engla/keybinder/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86"
+IUSE="+introspection lua python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND=">=x11-libs/gtk+-2.20:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrender
+	introspection? ( dev-libs/gobject-introspection )
+	lua? ( >=dev-lang/lua-5.1 )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-2.15.3:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable python)
+	)
+	# upstream failed at AC_ARG_ENABLE
+	use lua || myconf+=( --disable-lua )
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-libs/keybinder/keybinder-0.3.2-r300.ebuild b/dev-libs/keybinder/keybinder-0.3.2-r300.ebuild
index d12fc21e838b..074df4a90473 100644
--- a/dev-libs/keybinder/keybinder-0.3.2-r300.ebuild
+++ b/dev-libs/keybinder/keybinder-0.3.2-r300.ebuild
@@ -1,11 +1,9 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils
+EAPI=6
 
 MY_P=${PN}-3.0-${PV}
-
 DESCRIPTION="A library for registering global keyboard shortcuts"
 HOMEPAGE="https://github.com/engla/keybinder"
 SRC_URI="https://github.com/engla/keybinder/releases/download/${PN}-3.0-v${PV}/${MY_P}.tar.gz"
@@ -23,18 +21,19 @@ RDEPEND="x11-libs/gtk+:3
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
-DOCS="AUTHORS NEWS README"
-
 S=${WORKDIR}/${MY_P}
 
 src_configure() {
-	econf \
+	local myconf=(
 		$(use_enable introspection)
+	)
+
+	econf "${myconf[@]}"
 }
 
 src_install() {
 	default
-	prune_libtool_files --all
+	find "${D}" -name '*.la' -delete || die
 }
 
 pkg_preinst() {
-- 
cgit v1.2.3-65-gdbad