From 36f43d16ffbeb8b6751675c1b729dcf17b187a23 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Fri, 26 Jul 2019 19:52:11 +0300
Subject: dev-libs/libdazzle: bump to 3.32.3

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 dev-libs/libdazzle/Manifest                |  1 +
 dev-libs/libdazzle/libdazzle-3.32.3.ebuild | 56 ++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-libs/libdazzle/libdazzle-3.32.3.ebuild

(limited to 'dev-libs/libdazzle')

diff --git a/dev-libs/libdazzle/Manifest b/dev-libs/libdazzle/Manifest
index 9414304dbc59..5ac528fa74b7 100644
--- a/dev-libs/libdazzle/Manifest
+++ b/dev-libs/libdazzle/Manifest
@@ -1 +1,2 @@
 DIST libdazzle-3.30.2.tar.xz 432192 BLAKE2B 4c31b74b0a5c972b5c86bbacf50862a0c2db5c9ed1e67124671e2ece75d72de4c3605c6ecc81bde10cf2566ae06cbd7f14fccaff5d154c1bd9e53a9f8b2dc2eb SHA512 591c3bb9dd65ae02e6234a1599497dce78d843ee6ca47e8d50656b9f98bab91c7b89424c23eb387184bdb28132e1fbe11ee7c01d4a7f0598bcef92739aa8bff6
+DIST libdazzle-3.32.3.tar.xz 439492 BLAKE2B 7a8cf5a4ad29ca11b489553785e66d49a2ba7998f6791bb392ca37740441ff0e72f59ced192dc681ab20da79cb9183621a7d73baf57c9f045ae917fc993d1205 SHA512 e82d5f04706ec2003db27ece490255264828334d1e1c2076485660539664fd382c1289b9d8d4a6cc2dc31c65db270207e7d51105ffd1cadb7c384cd91199ceaa
diff --git a/dev-libs/libdazzle/libdazzle-3.32.3.ebuild b/dev-libs/libdazzle/libdazzle-3.32.3.ebuild
new file mode 100644
index 000000000000..ac1010df8633
--- /dev/null
+++ b/dev-libs/libdazzle/libdazzle-3.32.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Experimental new features for GTK+ and GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=x11-libs/gtk+-3.24.0:3[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
+BDEPEND="
+	>=dev-util/meson-0.49.0
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_tracing=false # extra trace debugging that would make things slower
+		-Denable_profiling=false # -pg passing
+		# -Denable_rdtscp=false # TODO: CPU_FLAGS_X86 for it?
+		-Denable_tools=true # /usr/bin/dazzle-list-counters
+		$(meson_use introspection with_introspection)
+		$(meson_use vala with_vapi)
+		$(meson_use gtk-doc enable_gtk_doc)
+		$(meson_use test enable_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
-- 
cgit v1.2.3-65-gdbad