From 1d74fa74001932ed9c51020ee952da3f672e6930 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 21 Feb 2020 07:35:55 +0100
Subject: dev-libs/libgit2: Bump to 0.99.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-libs/libgit2/Manifest              |  1 +
 dev-libs/libgit2/libgit2-0.99.0.ebuild | 73 ++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 dev-libs/libgit2/libgit2-0.99.0.ebuild

(limited to 'dev-libs/libgit2')

diff --git a/dev-libs/libgit2/Manifest b/dev-libs/libgit2/Manifest
index e0510a640a75..ed473e8907b3 100644
--- a/dev-libs/libgit2/Manifest
+++ b/dev-libs/libgit2/Manifest
@@ -1 +1,2 @@
 DIST libgit2-0.28.4.tar.gz 4991720 BLAKE2B 7dc94dce69c27f6de3736b94b4d80b727e3e2a7db255a9eab7422cebd93a3ea1a6f47d1de6c3fbe4ba5bcb28ade9b23a989c5b54c06eafeaf30e382f3b859cdf SHA512 b81160608003b25d9b922d259ebbbbf941b6bd5100fa1875497c8cd29de320e292fff568c757a7a85b2b3044ddc1cb92c74dbcb13d630d62ecf9a8559b619d15
+DIST libgit2-0.99.0.tar.gz 5307975 BLAKE2B 2ff6c48d29844c8efd292b636c018403f49ae5eef1ef41e2c8755cc35d935677fa965b52c05724aa133f8542a266bb0e0fabb34fcf710127332bd6137ea4ff12 SHA512 e38e18da0e6ed1e5c8198c9eb2c362b21da2d0b9c8bc23309d2f70183549f4b9f23a6db8ce5f1f0f24b373e6427039c2a845b62dd74f91b02cfe8954f961a91b
diff --git a/dev-libs/libgit2/libgit2-0.99.0.ebuild b/dev-libs/libgit2/libgit2-0.99.0.ebuild
new file mode 100644
index 000000000000..23bd171e3106
--- /dev/null
+++ b/dev-libs/libgit2/libgit2-0.99.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit cmake python-any-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~ppc-macos"
+fi
+
+DESCRIPTION="A linkable library for Git"
+HOMEPAGE="https://libgit2.org"
+
+LICENSE="GPL-2-with-linking-exception"
+SLOT="0/28"
+IUSE="examples gssapi libressl +ssh test +threads trace"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib
+	net-libs/http-parser:=
+	gssapi? ( virtual/krb5 )
+	ssh? ( net-libs/libssh2 )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+
+S=${WORKDIR}/${P/_/-}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
+		-DBUILD_CLAR=$(usex test)
+		-DENABLE_TRACE=$(usex trace)
+		-DUSE_GSSAPI=$(usex gssapi)
+		-DUSE_SSH=$(usex ssh)
+		-DTHREADSAFE=$(usex threads)
+		-DUSE_HTTP_PARSER=system
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	if [[ ${EUID} -eq 0 ]] ; then
+		# repo::iterator::fs_preserves_error fails if run as root
+		# since root can still access dirs with 0000 perms
+		ewarn "Skipping tests: non-root privileges are required for all tests to pass"
+	else
+		local TEST_VERBOSE=1
+		cmake_src_test -R offline
+	fi
+}
+
+src_install() {
+	cmake_src_install
+	dodoc docs/*.{md,txt}
+
+	if use examples ; then
+		find examples -name '.gitignore' -delete || die
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3-65-gdbad