From aae0e8513e3938e2dfe63f37bc74a510ecd34d3e Mon Sep 17 00:00:00 2001
From: "Andreas K. Hüttel" <dilfridge@gentoo.org>
Date: Fri, 23 Jul 2021 22:48:46 +0200
Subject: dev-perl/Pango: EAPI=7 bump
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
---
 dev-perl/Pango/Pango-1.227.0-r1.ebuild | 74 ----------------------------------
 dev-perl/Pango/Pango-1.227.0-r2.ebuild | 72 +++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+), 74 deletions(-)
 delete mode 100644 dev-perl/Pango/Pango-1.227.0-r1.ebuild
 create mode 100644 dev-perl/Pango/Pango-1.227.0-r2.ebuild

(limited to 'dev-perl')

diff --git a/dev-perl/Pango/Pango-1.227.0-r1.ebuild b/dev-perl/Pango/Pango-1.227.0-r1.ebuild
deleted file mode 100644
index 9b51b32f5fc7..000000000000
--- a/dev-perl/Pango/Pango-1.227.0-r1.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DIST_AUTHOR=XAOC
-DIST_VERSION=1.227
-VIRTUALX_REQUIRED=manual
-
-inherit perl-module virtualx
-
-DESCRIPTION="Layout and render international text"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc64-solaris ~x86-solaris"
-IUSE="examples test +minimal"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-perl/glib-perl-1.220.0
-	>=dev-perl/Cairo-1.0.0
-	>=x11-libs/pango-1.0.0
-"
-DEPEND="
-	${RDEPEND}
-	virtual/perl-ExtUtils-MakeMaker
-	>=dev-perl/ExtUtils-Depends-0.300.0
-	>=dev-perl/ExtUtils-PkgConfig-1.30.0
-	test? (
-		virtual/perl-Test-Simple
-		!minimal? (
-			>=dev-perl/Gtk2-1.220.0
-			$VIRTUALX_DEPEND
-		)
-	)
-"
-
-src_prepare() {
-	perl-module_src_prepare
-	sed -i -e "s:exit 0:exit 1:g" "${S}"/Makefile.PL || die "sed failed"
-}
-src_install() {
-	local mydoc
-	mydoc=("NEWS")
-	perl-module_src_install
-	if use examples; then
-		docompress -x /usr/share/doc/${PF}/examples
-		insinto /usr/share/doc/${PF}/examples
-		doins examples/*
-	fi
-}
-src_test() {
-	local MODULES=( "Pango ${DIST_VERSION}" )
-	local failed=()
-	for dep in "${MODULES[@]}"; do
-		ebegin "Compile testing ${dep}"
-			perl -Mblib="${S}/blib" -M"${dep} ()" -e1
-		eend $? || failed+=( "$dep" )
-	done
-	if [[ ${failed[@]} ]]; then
-		echo
-		eerror "One or more modules failed compile:";
-		for dep in "${failed[@]}"; do
-			 eerror "  ${dep}"
-		done
-		die "Failing due to module compilation errors";
-	fi
-	if use minimal; then
-		einfo "Skipping builtin tests due to USE=minimal"
-	else
-		virtx perl-module_src_test
-	fi
-}
diff --git a/dev-perl/Pango/Pango-1.227.0-r2.ebuild b/dev-perl/Pango/Pango-1.227.0-r2.ebuild
new file mode 100644
index 000000000000..4732764d1bbf
--- /dev/null
+++ b/dev-perl/Pango/Pango-1.227.0-r2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=XAOC
+DIST_VERSION=1.227
+DIST_EXAMPLES=( "examples/*" )
+VIRTUALX_REQUIRED=manual
+
+inherit perl-module virtualx
+
+DESCRIPTION="Layout and render international text"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc64-solaris ~x86-solaris"
+IUSE="test +minimal"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-perl/glib-perl-1.220.0
+	>=dev-perl/Cairo-1.0.0
+	>=x11-libs/pango-1.0.0
+"
+BDEPEND="
+	${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	>=dev-perl/ExtUtils-Depends-0.300.0
+	>=dev-perl/ExtUtils-PkgConfig-1.30.0
+	test? (
+		virtual/perl-Test-Simple
+		!minimal? (
+			>=dev-perl/Gtk2-1.220.0
+			$VIRTUALX_DEPEND
+		)
+	)
+"
+
+src_prepare() {
+	perl-module_src_prepare
+	sed -i -e "s:exit 0:exit 1:g" "${S}"/Makefile.PL || die "sed failed"
+}
+
+src_install() {
+	local mydoc
+	mydoc=("NEWS")
+	perl-module_src_install
+}
+
+src_test() {
+	local MODULES=( "Pango ${DIST_VERSION}" )
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}/blib" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			 eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	if use minimal; then
+		einfo "Skipping builtin tests due to USE=minimal"
+	else
+		virtx perl-module_src_test
+	fi
+}
-- 
cgit v1.2.3-65-gdbad