From 78e9f890907b0a2b514fca7433a1108d1096cd9d Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 4 Mar 2021 22:07:39 +0100
Subject: dev-python/jaraco-path: New dep of setuptools
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/jaraco-path/Manifest                 |  1 +
 dev-python/jaraco-path/jaraco-path-3.3.1.ebuild | 40 +++++++++++++++++++++++++
 dev-python/jaraco-path/metadata.xml             | 13 ++++++++
 3 files changed, 54 insertions(+)
 create mode 100644 dev-python/jaraco-path/Manifest
 create mode 100644 dev-python/jaraco-path/jaraco-path-3.3.1.ebuild
 create mode 100644 dev-python/jaraco-path/metadata.xml

(limited to 'dev-python/jaraco-path')

diff --git a/dev-python/jaraco-path/Manifest b/dev-python/jaraco-path/Manifest
new file mode 100644
index 000000000000..fdfb98c99971
--- /dev/null
+++ b/dev-python/jaraco-path/Manifest
@@ -0,0 +1 @@
+DIST jaraco.path-3.3.1.tar.gz 13287 BLAKE2B 8a803269fc02cc85391b4b1e1f2ee2a94c039d433b505aeb4aa0fcbb23731b802f236cd2de80dbb8b9e59297312892a085632f41234d3e1bb7d4bd04f62e00ba SHA512 00dac02fdc6df469f8661d552b16a8ee6150d86a7df9459264377a03e96fd94608f9782ad4cc2b2df67c64a10f8af26ed650b0bac0b1e59607d429abdbe64309
diff --git a/dev-python/jaraco-path/jaraco-path-3.3.1.ebuild b/dev-python/jaraco-path/jaraco-path-3.3.1.ebuild
new file mode 100644
index 000000000000..d718b3dcdb27
--- /dev/null
+++ b/dev-python/jaraco-path/jaraco-path-3.3.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+MY_P="${P/-/.}"
+DESCRIPTION="Miscellaneous path functions"
+HOMEPAGE="https://github.com/jaraco/jaraco.path/"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-8.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+src_prepare() {
+	# use the py3.7+ built-in
+	sed -i -e '/singledispatch/d' setup.cfg || die
+	sed -i -e 's:from singledispatch:from functools:' jaraco/path.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv tests || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/jaraco-path/metadata.xml b/dev-python/jaraco-path/metadata.xml
new file mode 100644
index 000000000000..1a2842629b40
--- /dev/null
+++ b/dev-python/jaraco-path/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">jaraco.path</remote-id>
+		<remote-id type="github">jaraco/jaraco.path</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad