From 4f3b3e2d24d2f959231e4f86b2d0b5d9b34455a6 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sautier.louis@gmail.com>
Date: Thu, 19 Jan 2017 23:37:42 +0100
Subject: dev-python/libvirt-python: add py3.5, examples, EAPI=6, re-enable
 tests

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Signed-off-by: Matthias Maier <tamiko@gentoo.org>
---
 .../libvirt-python/libvirt-python-2.5.0-r1.ebuild  | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/libvirt-python/libvirt-python-2.5.0-r1.ebuild

(limited to 'dev-python/libvirt-python')

diff --git a/dev-python/libvirt-python/libvirt-python-2.5.0-r1.ebuild b/dev-python/libvirt-python/libvirt-python-2.5.0-r1.ebuild
new file mode 100644
index 000000000000..d2c9b6797911
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-2.5.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+MY_P="${P/_rc/-rc}"
+
+inherit distutils-r1
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://libvirt.org/libvirt-python.git"
+	SRC_URI=""
+	KEYWORDS=""
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad