From 184cc973fbf6d76c5c0912d55eff9aed5da52048 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 24 Nov 2020 12:39:11 +0000
Subject: dev-python/sympy: bump to 1.7_rc1

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-python/sympy/Manifest             |  1 +
 dev-python/sympy/sympy-1.7_rc1.ebuild | 66 +++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-python/sympy/sympy-1.7_rc1.ebuild

(limited to 'dev-python/sympy')

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index a334805622da..6b9a378ad3ec 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
 DIST sympy-1.6.2.tar.gz 6811705 BLAKE2B 4cd894d28bedc986acc8ef67aa60f82e0899c2ed028658a8f340d7538b890e0ed380b3614a464eb58d71873b29b0795508b4556bb8115bf0c108336ef1e4cca3 SHA512 e16a1d85aba438e4248bac48a163ea1827e2cee57c28f7670ed19cc69d4c08d6796d62f79d245e269d75765b8f7ff4f4ca2841f98534e136ceeb5d3f7a5d252a
+DIST sympy-1.7rc1.tar.gz 6969788 BLAKE2B d7429aa6fde9943926cc14d77fe71e94b50e2329e56854d6e59ab6d2a09f659458d6baf18f36ed0b33e5add5fb0e38064730e4603e86f8edb8106683ff8063ab SHA512 7ffa8254ceeb0cd68c03503aa7ac662f2f8fe07aec0d3e6dc0afdca4e14b674e6b9db2feea79f272b9fae398d7c9edf49ac235526b5949262ca6ea8e412b9029
diff --git a/dev-python/sympy/sympy-1.7_rc1.ebuild b/dev-python/sympy/sympy-1.7_rc1.ebuild
new file mode 100644
index 000000000000..a6d4c8f25b0e
--- /dev/null
+++ b/dev-python/sympy/sympy-1.7_rc1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://sympy.org"
+SRC_URI="https://github.com/sympy/sympy/archive/${P/_/}.tar.gz"
+S="${WORKDIR}/${PN}-${P/_/}"
+
+LICENSE="BSD"
+SLOT="0"
+#KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs theano"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND="dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+	theano? ( dev-python/theano[${PYTHON_USEDEP}] )
+"
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" setup.py test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}
-- 
cgit v1.2.3-65-gdbad