From 40eae544d0639e2a9a208d590bd0b93ce1ab65a9 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 2 Aug 2020 18:58:52 +0000
Subject: dev-python/sympy: bump to 1.6.1

* Bump to 1.6.1
* Add Python 3.8, 3.9
* Unrestrict tests (all pass here)

Closes: https://bugs.gentoo.org/722546
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-python/sympy/Manifest           |  1 +
 dev-python/sympy/sympy-1.6.1.ebuild | 65 +++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)
 create mode 100644 dev-python/sympy/sympy-1.6.1.ebuild

(limited to 'dev-python/sympy')

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index b8791fc94efc..ed15a2352fdf 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
 DIST sympy-1.5.1.tar.gz 6815997 BLAKE2B bc74d01fdf2ccea6b83a06c11f810e3d105e9d35b397c8b87a1bcc4e316d00c456f576baf57d1b4a6175e056dec58f05fbb05893519775ffa252ac018452d2ff SHA512 3c4220243d2cbcff9eedb2a7986431b5b4d7d0007c78208a60b21830c9a3528d2171086874c42205c1227f779e44c19b9562943e2935d329bc352e7ea85396c7
+DIST sympy-1.6.1.tar.gz 6811393 BLAKE2B cd19946fc726b5a74f9ff0af07f07f8f76ea28b20818653d785848e331c126d634d8167e3506d8b87c12ed057df4a59551f0a0214b7d1292e199c6a3353f70be SHA512 95630b6fad1e41f2d58d1f4f4433ef76d4553f3e119bfdd36048c5880ac7f07d572e901eaae0b5c6208f598989a86ab5e03932a851f8048c584154973be6982c
diff --git a/dev-python/sympy/sympy-1.6.1.ebuild b/dev-python/sympy/sympy-1.6.1.ebuild
new file mode 100644
index 000000000000..adb5f1ab365b
--- /dev/null
+++ b/dev-python/sympy/sympy-1.6.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1 eutils virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://sympy.org"
+SRC_URI="https://github.com/sympy/sympy/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs theano"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND="dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+	theano? ( dev-python/theano[${PYTHON_USEDEP}] )
+"
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" setup.py test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}
-- 
cgit v1.2.3-65-gdbad