From 29c378d889d06d2f1631a4e36750bec7fbd2269a Mon Sep 17 00:00:00 2001
From: Jakov Smolic <jakov.smolic@sartura.hr>
Date: Sat, 15 Aug 2020 15:44:15 +0200
Subject: dev-util/cgdb: revbump for bugfixes

Closes: https://bugs.gentoo.org/730138
Closes: https://bugs.gentoo.org/682386
Closes: https://bugs.gentoo.org/678006
Closes: https://bugs.gentoo.org/630512
Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-util/cgdb/cgdb-0.7.0-r2.ebuild | 68 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 dev-util/cgdb/cgdb-0.7.0-r2.ebuild

(limited to 'dev-util/cgdb')

diff --git a/dev-util/cgdb/cgdb-0.7.0-r2.ebuild b/dev-util/cgdb/cgdb-0.7.0-r2.ebuild
new file mode 100644
index 000000000000..41d85a3805a1
--- /dev/null
+++ b/dev-util/cgdb/cgdb-0.7.0-r2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="
+		https://github.com/cgdb/cgdb.git
+		git@github.com:cgdb/cgdb.git"
+else
+	SRC_URI="https://github.com/cgdb/cgdb/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+inherit multilib-minimal
+
+DESCRIPTION="A curses front-end for GDB, the GNU debugger"
+HOMEPAGE="http://cgdb.github.io/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0="
+
+BDEPEND="
+	test? (
+		dev-util/dejagnu
+		app-misc/dtach
+	)"
+
+RDEPEND="
+	${DEPEND}
+	sys-devel/gdb"
+
+DOCS=( AUTHORS ChangeLog FAQ INSTALL NEWS README.md )
+
+PATCHES=(
+	# Bugs: #730138, #678006, #630512, #682386
+	"${FILESDIR}/${PN}-test.patch"
+)
+
+src_prepare() {
+	default
+	./autogen.sh || die
+}
+
+multilib_src_test() {
+	# Tests need an interactive shell, #654986
+
+	# real-time output of the log ;-)
+	touch "${T}/dtach-test.log" || die
+	tail -f "${T}/dtach-test.log" &
+	local tail_pid=${!}
+
+	nonfatal dtach -N "${T}/dtach.sock" \
+		bash -c 'emake check &> "${T}"/dtach-test.log; echo ${?} > "${T}"/dtach-test.out'
+
+	kill "${tail_pid}"
+	[[ -f ${T}/dtach-test.out ]] || die "Unable to run tests"
+	[[ $(<"${T}"/dtach-test.out) == 0 ]] || die "Tests failed"
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf
+}
-- 
cgit v1.2.3-65-gdbad