From 4c0785fe0b8191b752315b3f26ea7657cb9b5a3e Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Sat, 17 Nov 2018 19:14:00 +1100
Subject: dev-util/cmocka: version bump 1.1.3

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>
---
 dev-util/cmocka/cmocka-1.1.3.ebuild | 47 +++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-util/cmocka/cmocka-1.1.3.ebuild

(limited to 'dev-util/cmocka/cmocka-1.1.3.ebuild')

diff --git a/dev-util/cmocka/cmocka-1.1.3.ebuild b/dev-util/cmocka/cmocka-1.1.3.ebuild
new file mode 100644
index 000000000000..6ae39d5ba5d4
--- /dev/null
+++ b/dev-util/cmocka/cmocka-1.1.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-multilib
+
+DESCRIPTION="A unit testing framework for C"
+HOMEPAGE="https://cmocka.org/"
+SRC_URI="https://cmocka.org/files/1.1/${P}.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc static-libs test"
+
+DEPEND="
+	doc? ( app-doc/doxygen[latex] )
+"
+RDEPEND=""
+
+DOCS=( AUTHORS ChangeLog README.md )
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DWITH_STATIC_LIB=$(usex static-libs)
+		-DUNIT_TESTING=$(usex test)
+		$(multilib_is_native_abi && cmake-utils_use_find_package doc Doxygen \
+			|| echo -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON)
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi && use doc; then
+		pushd doc || die
+		doxygen Doxyfile || die
+		rm -f html/*.md5 latex/*.md5 latex/Manifest man/man3/_* || die
+		dodoc -r html/
+		dodoc -r latex/
+		doman man/man3/*.3
+		popd || die
+	fi
+
+	cmake-utils_src_install
+}
-- 
cgit v1.2.3-65-gdbad