From d31a5b37c1cfd21c90ad5678c889f21eff14604e Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Thu, 29 Jul 2021 13:12:11 -0700
Subject: dev-util/umockdev: Version bump to 0.16.1

Based on an ebuild by Fabio Scaccabarozzi <fsvm88@gmail.com>

Closes: https://bugs.gentoo.org/779748
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-util/umockdev/Manifest               |  1 +
 dev-util/umockdev/umockdev-0.16.1.ebuild | 52 ++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-util/umockdev/umockdev-0.16.1.ebuild

(limited to 'dev-util/umockdev')

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index 976dbbd1c422..c6d45dc28fc7 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1 +1,2 @@
 DIST umockdev-0.12.1.tar.xz 756920 BLAKE2B a8c1d9734f4c0a8e7f19405e011ce964efce6621b4886efead88e040bfe07d2f5a85f063977dfed1c8fb5a5bf4668024b6e687b688a9609cdba1db419518a8ac SHA512 a8995d09179c7d2d37d319f8e675fb15c3caa605c57b56cbb2e785088909d886e790864475feb82ab2b6eb2449038c636a06250d4f9eb8b28b38f0d80574824c
+DIST umockdev-0.16.1.tar.xz 478308 BLAKE2B 3d49ca1d9c9b7573ac63f5f7ecd81071041597732b507619c333379095434ac55eb26f16bdf5897b94bbeb5c307a34b703accd220cd6202482e172dd3a6d1983 SHA512 baeaf05cc6b8d8e2a5cae16b808db759a18a969cea0f2ceed5f6c2521edc0c4c07dc16265a4821051de51f4314fd39d63ebf2da124fcd3e103ec743dadfedaa8
diff --git a/dev-util/umockdev/umockdev-0.16.1.ebuild b/dev-util/umockdev/umockdev-0.16.1.ebuild
new file mode 100644
index 000000000000..ad527911b174
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.16.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_src_prepare
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}
-- 
cgit v1.2.3-65-gdbad