From 776ebddc04e9e262e6d187902cd914f821d230ea Mon Sep 17 00:00:00 2001
From: Alexey Sokolov <alexey+gentoo@asokolov.org>
Date: Fri, 27 Aug 2021 17:09:42 +0100
Subject: games-puzzle/xbomb: various fixes, bump eapi

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Closes: https://bugs.gentoo.org/710600
Closes: https://github.com/gentoo/gentoo/pull/22130
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 games-puzzle/xbomb/xbomb-2.2b-r2.ebuild | 55 -------------------------------
 games-puzzle/xbomb/xbomb-2.2b-r3.ebuild | 57 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+), 55 deletions(-)
 delete mode 100644 games-puzzle/xbomb/xbomb-2.2b-r2.ebuild
 create mode 100644 games-puzzle/xbomb/xbomb-2.2b-r3.ebuild

(limited to 'games-puzzle')

diff --git a/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild b/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild
deleted file mode 100644
index d43f0aec54a7..000000000000
--- a/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit desktop toolchain-funcs
-
-DESCRIPTION="Minesweeper clone with hexagonal, rectangular and triangular grid"
-HOMEPAGE="http://www.gedanken.org.uk/software/xbomb/"
-SRC_URI="http://www.gedanken.org.uk/software/xbomb/download/${P}.tgz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc64 ~x86"
-
-DEPEND="x11-libs/libXaw"
-RDEPEND="
-	${DEPEND}
-	acct-group/gamestat
-"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-DESTDIR.patch
-	"${FILESDIR}"/${P}-ldflags.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i \
-		-e '/strip/d' \
-		-e '/^CC=/d' \
-		-e "/^CFLAGS/ { s:=.*:=${CFLAGS}: }" \
-		Makefile || die
-	sed -i \
-		-e "s:/var/tmp:/var/lib/${PN}:g" \
-		hiscore.c || die
-}
-
-src_configure() {
-	tc-export CC
-}
-
-src_install() {
-	default
-
-	dodir /var/lib/${PN}
-	touch "${ED}"/var/lib/${PN}/${PN}{3,4,6}.hi || die "touch failed"
-	fperms 660 /var/lib/${PN}/${PN}{3,4,6}.hi
-
-	fowners root:gamestat /var/lib/${PN} /usr/bin/${PN}
-	fperms g+s /usr/bin/${PN}
-
-	make_desktop_entry xbomb XBomb
-}
diff --git a/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild b/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild
new file mode 100644
index 000000000000..f5c0a4225bea
--- /dev/null
+++ b/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Minesweeper clone with hexagonal, rectangular and triangular grid"
+HOMEPAGE="http://www.gedanken.org.uk/software/xbomb/"
+SRC_URI="http://www.gedanken.org.uk/software/xbomb/download/${P}.tgz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+DEPEND="
+	acct-group/gamestat
+	x11-libs/libX11
+	x11-libs/libXaw
+	x11-libs/libXt
+"
+RDEPEND="
+	${DEPEND}
+	media-fonts/font-misc-misc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-DESTDIR.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e '/strip/d' Makefile || die
+	sed -i \
+		-e "s:/var/tmp:${EPREFIX}/var/games/${PN}:g" \
+		hiscore.c || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	einstalldocs
+
+	dodir /var/games/${PN}
+	touch "${ED}"/var/games/${PN}/${PN}{3,4,6}.hi || die "touch failed"
+	fperms 660 /var/games/${PN}/${PN}{3,4,6}.hi
+
+	fowners root:gamestat /var/games/${PN} /usr/bin/${PN}
+	fperms g+s /usr/bin/${PN}
+
+	make_desktop_entry xbomb XBomb
+}
-- 
cgit v1.2.3-65-gdbad