From 93ac5a10c6de7338cb828211f8fe7d7372fbf50a Mon Sep 17 00:00:00 2001
From: Michael Sterrett <mr_bones_@gentoo.org>
Date: Sun, 8 May 2016 16:21:44 -0400
Subject: games-roguelike/angband: version bump (bug #582468)

Package-Manager: portage-2.2.26
---
 games-roguelike/angband/Manifest             |   1 +
 games-roguelike/angband/angband-4.0.5.ebuild | 117 +++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)
 create mode 100644 games-roguelike/angband/angband-4.0.5.ebuild

(limited to 'games-roguelike')

diff --git a/games-roguelike/angband/Manifest b/games-roguelike/angband/Manifest
index 5abfef6e7460..d6c6bb035ee5 100644
--- a/games-roguelike/angband/Manifest
+++ b/games-roguelike/angband/Manifest
@@ -1 +1,2 @@
 DIST angband-4.0.4.tar.gz 19888293 SHA256 93f95444304d5178d23569dbd3dbe1eb29747201d353c676206f26b5bec4667c SHA512 73dbf0782f042dbc5ee9fe42430041f447a58ec14076280d2d6a44ec2b338dd4a7c220dc36f1b214380852283fb0d6e56fb338c2da95911b450714fb7f71e680 WHIRLPOOL aafa1fb9f0a54f8a39cb194e86fc4df43f0d773da58703b401cda0856ef2f99db7f351f444a3e0405b140a6130dd2da6fb318fde0e66f143ad38c51b7b91fa73
+DIST angband-4.0.5.tar.gz 19886562 SHA256 0d769a0f349842b0c78cbcd1804a9e08f064e75ca26b957710e4c2a3eb14f852 SHA512 9ad46430d7e3c4b7676042b28107a2a5b9b2ed967dd1f45b91ca37583fa2d5e9ba25d963a6510ee091b8fdb3a704a60002d851d7898a6298567f804dce36a88b WHIRLPOOL f725bc940332b90081583f2eccc4890ce1a7a7426bd9f5ae69272beaaa79741797b46ffd283ec2969d14167c6c50d1ff738a573dade045bda79d0c7f51053e5a
diff --git a/games-roguelike/angband/angband-4.0.5.ebuild b/games-roguelike/angband/angband-4.0.5.ebuild
new file mode 100644
index 000000000000..8672d4152783
--- /dev/null
+++ b/games-roguelike/angband/angband-4.0.5.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils gnome2-utils versionator games
+
+MAJOR_PV=$(get_version_component_range 1-2)
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="http://rephial.org/"
+SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="ncurses sdl +sound X"
+
+RDEPEND="X? ( x11-libs/libX11 )
+	!ncurses? ( !X? ( !sdl? ( sys-libs/ncurses:0=[unicode] ) ) )
+	ncurses? ( sys-libs/ncurses:0=[unicode] )
+	sdl? ( media-libs/libsdl[video,X]
+		media-libs/sdl-ttf
+		media-libs/sdl-image
+		sound? ( media-libs/sdl-mixer[mp3]
+			media-libs/libsdl[sound] ) )"
+DEPEND="${RDEPEND}
+	dev-python/docutils
+	virtual/pkgconfig"
+
+src_prepare() {
+
+	sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
+	sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
+	sed -i -e '/^DOC =/s/=.*/=/' doc/Makefile || die
+
+	if use !sound ; then
+		sed -i -e 's/sounds//' lib/Makefile || die
+	fi
+
+	# Game constant files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	{
+		echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/customize/\""
+		echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/gamedata/\""
+	} > "${T}"/99${PN} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use sdl; then
+		myconf="$(use_enable sound sdl-mixer)"
+	else
+		myconf="--disable-sdl-mixer"
+	fi
+
+	ac_cv_path_NCURSES_CONFIG="pkg-config ncursesw" \
+	egamesconf \
+		--bindir="${GAMES_BINDIR}" \
+		--with-private-dirs \
+		$(use_enable X x11) \
+		$(use_enable sdl) \
+		$(use_enable ncurses curses) \
+		$(use !sdl && use !ncurses && use !X && \
+			echo --enable-curses) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="changes.txt faq.txt readme.txt thanks.txt" \
+		default
+
+	dohtml doc/manual.html
+	doenvd "${T}"/99${PN}
+
+	if use X || use sdl ; then
+		if use X; then
+			make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
+		fi
+
+		if use sdl; then
+			make_desktop_entry "angband -msdl" "Angband (SDL)" "${PN}"
+		fi
+
+		local s
+		for s in 16 32 128 256 512
+		do
+			newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
+		done
+		newicon -s scalable lib/icons/att.svg "${PN}.svg"
+	fi
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	if use X || use sdl ; then
+		gnome2_icon_savelist
+	fi
+}
+
+pkg_postinst() {
+	echo
+	elog "Angband now uses private savefiles instead of system-wide ones."
+	elog "This version of Angband is not compatible with the save files"
+	elog "of previous versions."
+	echo
+
+	games_pkg_postinst
+	if use X || use sdl ; then
+		gnome2_icon_cache_update
+	fi
+}
-- 
cgit v1.2.3-18-g5258