From da2e546d69fe90fc93ea4bf4cb1bc32aa7fc7e8e Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Tue, 25 Jul 2017 14:02:16 +0200
Subject: gnustep-libs/sope: 3.2.10 bump

Package-Manager: Portage-2.3.6, Repoman-2.3.3
---
 gnustep-libs/sope/Manifest           |  1 +
 gnustep-libs/sope/sope-3.2.10.ebuild | 62 ++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 gnustep-libs/sope/sope-3.2.10.ebuild

(limited to 'gnustep-libs')

diff --git a/gnustep-libs/sope/Manifest b/gnustep-libs/sope/Manifest
index b4c2a3e10983..f0e704ca78f3 100644
--- a/gnustep-libs/sope/Manifest
+++ b/gnustep-libs/sope/Manifest
@@ -1 +1,2 @@
+DIST sope-3.2.10.tar.gz 2197170 SHA256 33fee3e5d69bdf7977795343a1c397f363883312d50404a45f80989a624d950f SHA512 09c0e8ca7333e89c48e30b19dc3bbacca5a28688145848ff332ff304f92a791b3895774e5fd1f77c6d4c8615ecb5a461ba348792502fc7c5bbd9d445a191bccf WHIRLPOOL dabab42e668850cd64be1e235d30e39de3eab3ccd2e98daf70f2e8537e1e06076fbf14316073b3f320f29556eb8b1cc3550c6a8ef0f579398df099cbb4bad242
 DIST sope-3.2.9.tar.gz 2196831 SHA256 bcbbfab4e4f8dcc536992d54f6e0b6734d2009233428622009e5dac78c622f2e SHA512 ffa3d63eed5862aba9740ab84408297218ad6cd75b0dc7e40f2810366281bf139c55e27c11405b51dc1cf640d5f5434ee14c2d5f1d0384ad50684c23d8bc58b7 WHIRLPOOL 241e056333e9355cf4453ed4505233238fef09c85f1f41d151866eed8ed09ab3f70f1b907e5bbe9941ea5b11500cf13a3d7b816c00f6367de3613d6332617c84
diff --git a/gnustep-libs/sope/sope-3.2.10.ebuild b/gnustep-libs/sope/sope-3.2.10.ebuild
new file mode 100644
index 000000000000..550358b4884d
--- /dev/null
+++ b/gnustep-libs/sope/sope-3.2.10.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gnustep-2 vcs-snapshot
+
+DESCRIPTION="A set of frameworks forming a complete Web application server environment"
+HOMEPAGE="http://www.sogo.nu/"
+SRC_URI="https://github.com/inverse-inc/sope/archive/SOPE-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnutls ldap libressl mysql postgres +ssl +xml"
+
+RDEPEND="
+	sys-libs/zlib
+	ldap? ( net-nds/openldap )
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+	mysql? ( virtual/libmysqlclient:= )
+	postgres? ( dev-db/postgresql:= )
+	xml? ( dev-libs/libxml2:2 )
+"
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	if use ssl && use gnutls && use libressl ; then
+		ewarn "You have enabled both gnutls and libressl, but only"
+		ewarn "one provider can be active. Using gnutls!"
+	fi
+}
+
+src_configure() {
+	local ssl_provider
+	if use ssl ; then
+		if use gnutls ; then
+			ssl_provider=gnutls
+		else
+			ssl_provider=ssl
+		fi
+	else
+		ssl_provider=none
+	fi
+
+	egnustep_env
+
+	# Non-standard configure script
+	./configure \
+		--disable-strip \
+		$(use_enable debug) \
+		$(use_enable ldap openldap) \
+		$(use_enable mysql) \
+		$(use_enable postgres postgresql) \
+		$(use_enable xml) \
+		--with-ssl="${ssl_provider}" \
+		--with-gnustep || die "configure failed"
+}
-- 
cgit v1.2.3