From 6de24fcbe1f97ad818224740e7be4b3da3cbb54b Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Fri, 3 May 2019 13:22:25 -0500
Subject: gui-apps/swaylock: 1.4 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
---
 gui-apps/swaylock/Manifest             |  1 +
 gui-apps/swaylock/swaylock-1.4.ebuild  | 61 ++++++++++++++++++++++++++++++++++
 gui-apps/swaylock/swaylock-9999.ebuild |  2 +-
 3 files changed, 63 insertions(+), 1 deletion(-)
 create mode 100644 gui-apps/swaylock/swaylock-1.4.ebuild

(limited to 'gui-apps')

diff --git a/gui-apps/swaylock/Manifest b/gui-apps/swaylock/Manifest
index ee04cb54cdea..30978a155d03 100644
--- a/gui-apps/swaylock/Manifest
+++ b/gui-apps/swaylock/Manifest
@@ -1 +1,2 @@
 DIST swaylock-1.3.tar.gz 32848 BLAKE2B 81ed50839bcb0139e7fc2081bd37e738f3e6ef23e96a5108d1acf56cc3425285f7382576a54201f1bf188883b1da06492074c091877af13832c0140e4e6099fd SHA512 723d758d76f076f3f1539ea0d651f6ad2562659c72eef7e895d7827a0be21db663652fe4ce2609065aff45ff20230879599868cff327ab52b896330ca04d78c4
+DIST swaylock-1.4.tar.gz 34288 BLAKE2B 6b2c8764fd605b04843c254e776f7174caedf4f0dbc85cbd9b5cc10762eed5694ac2fdaa0393a630afc374980f0d6530104119505f034d65af37d738ab1a30fc SHA512 5068b5f97e3094c511deda553f363a71f655b16e6533ef8f82befcd3b9027a55de81f143eb95e60cf4dbe4cecdc49906285bd6a0e6d51eb3b2807d0101581809
diff --git a/gui-apps/swaylock/swaylock-1.4.ebuild b/gui-apps/swaylock/swaylock-1.4.ebuild
new file mode 100644
index 000000000000..930e13f924be
--- /dev/null
+++ b/gui-apps/swaylock/swaylock-1.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Screen locker for Wayland"
+HOMEPAGE="https://github.com/swaywm/swaylock"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="fish-completion +gdk-pixbuf +man +pam zsh-completion"
+
+DEPEND="
+	dev-libs/wayland
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	pam? ( virtual/pam )
+"
+RDEPEND="
+	${DEPEND}
+	!<=gui-wm/sway-1.0_beta2[swaylock]
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		-Dpam=$(usex pam enabled disabled)
+		-Dgdk-pixbuf=$(usex gdk-pixbuf enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if [[ ${PV} != 9999 ]]; then
+		emesonargs+=("-Dswaylock-version=${PV}")
+	fi
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	if ! use pam; then
+		fcaps cap_sys_admin usr/bin/swaylock
+	fi
+}
diff --git a/gui-apps/swaylock/swaylock-9999.ebuild b/gui-apps/swaylock/swaylock-9999.ebuild
index 5ea7fb975255..930e13f924be 100644
--- a/gui-apps/swaylock/swaylock-9999.ebuild
+++ b/gui-apps/swaylock/swaylock-9999.ebuild
@@ -13,7 +13,7 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
 else
 	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~amd64 ~arm64 ~x86"
 fi
 
 LICENSE="MIT"
-- 
cgit v1.2.3-65-gdbad