From 4596f01b1eeebf3ee9cb8ec94f694191e4150c0b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 8 Nov 2018 12:48:51 +0100
Subject: kde-apps: Add KDE Applications 18.08.3

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/kwave/Manifest             |  1 +
 kde-apps/kwave/kwave-18.08.3.ebuild | 82 +++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100644 kde-apps/kwave/kwave-18.08.3.ebuild

(limited to 'kde-apps/kwave')

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index b192331f2467..24da06c8f22c 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-18.04.3.tar.xz 6186388 BLAKE2B 4c6d4c9d2beeacee09535930e5660cde084105a9bed21ef4df400fbe8f5b0ccbdc5eb0152f08a92bbe60b7eb164b268964f6b386af0740677d99c2f1abe2dc9f SHA512 30fdfdf681bdf2f339a0b8ca91899e4b3e447075a7454f352f897745af2b671a5412c37ff372563a5f80cb3545295a5c4849b3243386ab86831e325867f7ef23
 DIST kwave-18.08.2.tar.xz 6215428 BLAKE2B adb9f160b576ce4c7e7bd99ee5a20a4075812138f1232990967cc0849e48d4bf03972756abd8fdfd9c4bca6ad4d1bc7874d8a79f078c8777de22f8d4e8afc8e9 SHA512 31e971799d79cde4dac118121a8ca4d89910c8599f7b019e26e10bae63a892e53e022386e03a0703ff2a1c03b6121ff1761a89ce59903f49d8da6f23a039a58a
+DIST kwave-18.08.3.tar.xz 6214600 BLAKE2B 1ef161d62de71d60ff2e8507bf5ddf2a8e778c2ae62b08669d481f41223ec2e7273257440aaa21a53063aa4c072a3303901f2fa027318b21a3d7f33e825ecef7 SHA512 ddce5e748403e0678fa6713521713b5320b3c8732e5e70cb056b3c2da63e6480e47a47112521266d9df31ffd7750fa6c29485ee45bfdfbc215e3b3013173e469
diff --git a/kde-apps/kwave/kwave-18.08.3.ebuild b/kde-apps/kwave/kwave-18.08.3.ebuild
new file mode 100644
index 000000000000..5332d69756bd
--- /dev/null
+++ b/kde-apps/kwave/kwave-18.08.3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="http://kwave.sourceforge.net/ https://www.kde.org/applications/multimedia/kwave/"
+LICENSE="
+	CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+
+	handbook? ( FDL-1.2 )
+	opus? ( BSD-2 )
+"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| ( media-sound/lame media-sound/toolame media-sound/twolame )
+	)
+	qtmedia? ( $(add_qt_dep qtmultimedia) )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_kdeapps_dep poxml)
+	$(add_qt_dep qtconcurrent)
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	kde5_src_configure
+}
-- 
cgit v1.2.3-65-gdbad