From 3a97b1edecd630c0f48d3b0a28f053b0489a9597 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 2 Jan 2018 21:32:04 +0100
Subject: kde-plasma: Add KDE Plasma 5.11.5

See also:
https://www.kde.org/announcements/plasma-5.11.4-5.11.5-changelog.php

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 .../kde-gtk-config/kde-gtk-config-5.11.5.ebuild    | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 kde-plasma/kde-gtk-config/kde-gtk-config-5.11.5.ebuild

(limited to 'kde-plasma/kde-gtk-config/kde-gtk-config-5.11.5.ebuild')

diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.11.5.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.11.5.ebuild
new file mode 100644
index 000000000000..c986c5d01377
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.11.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma systemsettings kcm to set GTK application look&feel"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+gtk3"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	dev-libs/glib:2
+	x11-libs/gtk+:2
+	x11-libs/libXcursor
+	gtk3? ( x11-libs/gtk+:3 )
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+	!kde-plasma/kde-gtk-config:4
+"
+
+RESTRICT+=" test"
+
+PATCHES=( "${FILESDIR}/${PN}-5.4.2-gtk3-optional.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+		-DBUILD_gtk3proxies=$(usex gtk3)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	einfo
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+	einfo
+}
-- 
cgit v1.2.3