From 56148d2ee3e83c17a64f8672d32143bcb2f56e02 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 23 Oct 2018 18:51:56 +0200
Subject: kde-plasma: Add KDE Plasma 5.14.2

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11
---
 .../xembed-sni-proxy-5.14.2.ebuild                 | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.14.2.ebuild

(limited to 'kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.14.2.ebuild')

diff --git a/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.14.2.ebuild b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.14.2.ebuild
new file mode 100644
index 000000000000..74322bcb6432
--- /dev/null
+++ b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.14.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+FRAMEWORKS_MINIMAL="5.50.0"
+QT_MINIMAL="5.9.6"
+KDE_AUTODEPS="false"
+KMNAME="plasma-workspace"
+inherit kde5
+
+DESCRIPTION="Legacy xembed tray icons support for SNI-only system trays"
+HOMEPAGE="https://cgit.kde.org/plasma-workspace.git/tree/xembed-sni-proxy/Readme.md"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~x86"
+
+DEPEND="
+	$(add_frameworks_dep extra-cmake-modules)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtcore)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libxcb
+	x11-libs/libXtst
+	x11-libs/xcb-util-image
+"
+RDEPEND="${DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+	!kde-plasma/xembed-sni-proxy:0
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.14.2-standalone.patch" )
+
+src_prepare() {
+	kde5_src_prepare
+
+	sed -e "/set/s/GENTOO_PV/${PV}/" \
+		-e "/set/s/GENTOO_QT_MINIMAL/${QT_MINIMAL}/" \
+		-e "/set/s/GENTOO_KF5_MINIMAL/${FRAMEWORKS_MINIMAL}/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}
-- 
cgit v1.2.3-65-gdbad