From 874208a76e2a02d6a911f5612ffa1dbdc34248fb Mon Sep 17 00:00:00 2001
From: Dirkjan Ochtman <djc@gentoo.org>
Date: Wed, 27 Jan 2016 15:19:34 +0100
Subject: mail-filter/rspamd: add jit USE flag (fixes bug 572682)

---
 mail-filter/rspamd/rspamd-1.1.1-r1.ebuild | 62 +++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 mail-filter/rspamd/rspamd-1.1.1-r1.ebuild

(limited to 'mail-filter')

diff --git a/mail-filter/rspamd/rspamd-1.1.1-r1.ebuild b/mail-filter/rspamd/rspamd-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..c5ecabb41092
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-1.1.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils user
+
+DESCRIPTION="Rapid spam filtering system"
+SRC_URI="https://rspamd.com/downloads/${P}.tar.xz"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+jit"
+
+DEPEND="dev-libs/openssl:0
+		jit? (
+			dev-libs/libpcre[jit]
+			dev-lang/luajit:2
+		)
+		!jit? (
+			dev-libs/libpcre[-jit]
+			>=dev-lang/lua-5.1:0
+		)
+		dev-libs/libevent
+		dev-db/sqlite:3
+		dev-libs/glib:2
+		dev-libs/gmime
+		sys-apps/file
+		virtual/libiconv"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+		-DENABLE_LUAJIT=$(usex jit)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newinitd "${FILESDIR}/rspamd.init" rspamd
+
+	dodir /var/lib/rspamd
+	dodir /var/log/rspamd
+
+	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/rspamd.logrotate" rspamd
+}
-- 
cgit v1.2.3-65-gdbad