From a8d21b852ffc74494636b5f0c844f838dfa44dad Mon Sep 17 00:00:00 2001
From: NP-Hardass <NP-Hardass@gentoo.org>
Date: Fri, 12 Aug 2016 00:47:41 -0400
Subject: mate-extra/mate-sensors-applet: 1.12.x vbump, add gtk3, from project
 repo

Package-Manager: portage-2.3.0
---
 .../mate-sensors-applet-1.12.1.ebuild              | 68 ++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 mate-extra/mate-sensors-applet/mate-sensors-applet-1.12.1.ebuild

(limited to 'mate-extra/mate-sensors-applet/mate-sensors-applet-1.12.1.ebuild')

diff --git a/mate-extra/mate-sensors-applet/mate-sensors-applet-1.12.1.ebuild b/mate-extra/mate-sensors-applet/mate-sensors-applet-1.12.1.ebuild
new file mode 100644
index 000000000000..8ba4ae9e360e
--- /dev/null
+++ b/mate-extra/mate-sensors-applet/mate-sensors-applet-1.12.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="MATE panel applet to display readings from hardware sensors"
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+dbus gtk3 hddtemp libnotify lm_sensors video_cards_fglrx video_cards_nvidia"
+
+RDEPEND="app-text/rarian:0
+	>=dev-libs/glib-2.36:2
+	>=mate-base/mate-panel-1.6[gtk3(-)=]
+	>=x11-libs/cairo-1.0.4:0
+	x11-libs/gdk-pixbuf:2
+	virtual/libintl:0
+	!gtk3? ( >=x11-libs/gtk+-2.24:2 )
+	gtk3? ( >=x11-libs/gtk+-3.0:3 )
+	hddtemp? (
+		dbus? (
+			>=dev-libs/dbus-glib-0.80:0
+			>=dev-libs/libatasmart-0.16:0 )
+		!dbus? ( >=app-admin/hddtemp-0.3_beta13:0 ) )
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	lm_sensors? ( sys-apps/lm_sensors:0 )
+	video_cards_fglrx? ( x11-drivers/ati-drivers:* )
+	video_cards_nvidia? ( || (
+		>=x11-drivers/nvidia-drivers-100.14.09:0[static-libs,tools]
+		media-video/nvidia-settings:0
+	) )"
+
+DEPEND="${RDEPEND}
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools:0
+	>=dev-util/intltool-0.50.1:*
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+PDEPEND="hddtemp? ( dbus? ( sys-fs/udisks:0 ) )"
+
+src_configure() {
+	local udisks
+
+	if use hddtemp && use dbus; then
+		udisks="--enable-udisks"
+	else
+		udisks="--disable-udisks"
+	fi
+
+	mate_src_configure \
+		--disable-static \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_enable libnotify) \
+		$(use_with lm_sensors libsensors) \
+		$(use_with video_cards_fglrx aticonfig) \
+		$(use_with video_cards_nvidia nvidia) \
+		${udisks}
+}
-- 
cgit v1.2.3-65-gdbad